_ ← ,⍥⊆   ⍝ Stranding function
¯2 ¯1 0 1 2 (↑ < _ ≤ _ = _ ≠ _ ≥ _ >) 0

groups   ← 'ABACC'
salaries ← 20000 25750 21000 32350 32400
salaries × 1.05 * groups = 'A'

values ← 4 10 6 8 16 24
names←'Anne' 'Ben' 'Charlie' 'Demi' 'Ella' 'Fiona'
(values≥10)/names

(+⌿÷≢)'the alphabet'∊'aeiou'

+/4 3 1 5   ⍝ Sum

+\4 3 1 5   ⍝ Cumulative sum

∧/1 1 1 1 1 1 1 1   ⍝ Are all true?
∧\1 1 0 1 1 1 0 1   ⍝ Were all true so far?
∨/0 0 1 0 0 0 0 0   ⍝ Are any true?
∨\0 0 1 0 0 0 1 0   ⍝ Were any true so far?

+/3 4 1 5
⊃⌽+\3 4 1 5

<\0 0 1 0 1 1 1 1 1 1 0 1 0 1 1

</0 0 0 1

⍝ <\0 1 0 1 1
0
0<1
0<1<0
0<1<0<1
0<1<0<1<1

code ← '+/⍳10   ⍝ sum⍝of⍝first⍝10⍝ints'
c ← code = '⍝'
↑ code c (<\c)

v ← '⍟⎕⍟⍟⍟⎕⎕⍟⎕⎕⍟⍟⍟⍟⎕⎕⎕⎕⍟⍟⎕⎕⎕⎕⍟⍟⎕⍟'
q ← '⎕'=v
↑v q (2</0,q)

≠/1 1 1 1
2|+/1 1 1 1

≠/1 1 1 0
2|+/1 1 1 0

b ← 0 0 1 0 0 0 1 0 0 0 0 1 0 0 1
↑ b (≠\b)

⍝ ≠\0 1 0 0 1
0
0≠1
0≠1≠0
0≠1≠0≠0
0≠1≠0≠0≠1

quoted ← 'extract the "quoted" parts from this "text"'
q ← '"'=quoted
inc ← (~∧≠\)'"'=quoted   ⍝ Including quote marks
exc ← (⊢∨≠\)'"'=quoted   ⍝ Exclusing quote marks
↑ quoted q inc exc

inc/quoted
exc⊆quoted

css ← '* {color: #000; /* text */ background: #fff; /* bg */}'
cpos ← '/*'∘(≠\⍷∨¯1⌽∘⌽⍷∘⌽)css
↑ css cpos

data ← (?9⍴100),(4 2 3⌿3 3⍴3/'ABC'),⍪?9⍴0

⎕←data

MTake ← ∊↑∘1¨
MTake 4 2 3

MTake ← {¯1⌽(⍳+/⍵)∊+\⍵}
MTake 4 2 3

MTake,4 2 3,⍤0⊢2

⎕←e←≠\MTake,4 2 3,⍤0⊢2

e⍀⍕data

labels ← (MTake 4 2 3)⍀(↑'Field '∘,¨'ABC')
e⍀⍕labels,data

1 0 0 0 1 0 0 {∊⌽¨⍺⊂⍵} 'ABCDXYZ'   ⍝ Reverse two parts independently

1 0 0 0 1 0 0 {∊+/¨⍺⊂⍵} ⍳7   ⍝ Sum two parts independently

_P ← {∊⍺⍺¨⍺⊂⍵}   ⍝ A partitioned-function-application operator
p ← 1 0 0 0 1 0 0
p ⌽ _P 'ABCDXYZ'
p +/_P ⍳7

a ← 'ABCDXYZ'
↑ a p (+\p)

⍒+\p

⌽⍒+\p

a[⌽⍒+\p]

+\⍳7

(1⌽p)/+\⍳7

¯2-/0,(1⌽p)/+\⍳7