# Custom solvers¶

In this example, we show how to define custom solvers. Our system will again be silicon, because we are not very imaginative

In :
using DFTK, LinearAlgebra

a = 10.26
lattice = a / 2 * [[0 1 1.];
[1 0 1.];
[1 1 0.]]
atoms = [Si => [ones(3)/8, -ones(3)/8]]

# We take very (very) crude parameters
model = model_LDA(lattice, atoms)
basis = PlaneWaveBasis(model; Ecut=5, kgrid=[1, 1, 1]);


We define our custom fix-point solver: simply a damped fixed-point

In :
function my_fp_solver(f, x0, max_iter; tol)
mixing_factor = .7
x = x0
fx = f(x)
for n = 1:max_iter
inc = fx - x
if norm(inc) < tol
break
end
x = x + mixing_factor * inc
fx = f(x)
end
(fixpoint=x, converged=norm(fx-x) < tol)
end;


Our eigenvalue solver just forms the dense matrix and diagonalizes it explicitly (this only works for very small systems)

In :
function my_eig_solver(A, X0; maxiter, tol, kwargs...)
n = size(X0, 2)
A = Array(A)
E = eigen(A)
λ = E.values[1:n]
X = E.vectors[:, 1:n]
(λ=λ, X=X, residual_norms=[], iterations=0, converged=true, n_matvec=0)
end;


Finally we also define our custom mixing scheme. It will be a mixture of simple mixing (for the first 2 steps) and than default to Kerker mixing. In the mixing interface δF is (ρ_\text{out} - ρ_\text{in}), i.e. the difference in density between two subsequent SCF steps and the mix function returns δρ, which is added to ρ_\text{in} to yield ρ_\text{next}, the density for the next SCF step.

In :
struct MyMixing
n_simple  # Number of iterations for simple mixing
end
MyMixing() = MyMixing(2)

function DFTK.mix_density(mixing::MyMixing, basis, δF; n_iter, kwargs...)
if n_iter <= mixing.n_simple
return δF  # Simple mixing -> Do not modify update at all
else
# Use the default KerkerMixing from DFTK
DFTK.mix_density(KerkerMixing(), basis, δF; kwargs...)
end
end


That's it! Now we just run the SCF with these solvers

In :
scfres = self_consistent_field(basis;
tol=1e-8,
solver=my_fp_solver,
eigensolver=my_eig_solver,
mixing=MyMixing());

n     Energy            Eₙ-Eₙ₋₁     ρout-ρin   α      Diag
---   ---------------   ---------   --------   ----   ----
1   -7.233800841938         NaN   3.18e-01   0.80    0.0
2   -7.247474454991   -1.37e-02   1.20e-01   0.80    0.0
3   -7.249052486158   -1.58e-03   4.56e-02   0.80    0.0
4   -7.249173983402   -1.21e-04   2.23e-02   0.80    0.0
5   -7.249205410444   -3.14e-05   1.11e-02   0.80    0.0
6   -7.249213694705   -8.28e-06   5.56e-03   0.80    0.0
7   -7.249215959961   -2.27e-06   2.85e-03   0.80    0.0
8   -7.249216608417   -6.48e-07   1.49e-03   0.80    0.0
9   -7.249216803146   -1.95e-07   7.91e-04   0.80    0.0
10   -7.249216864272   -6.11e-08   4.30e-04   0.80    0.0
11   -7.249216884190   -1.99e-08   2.38e-04   0.80    0.0
12   -7.249216890875   -6.68e-09   1.35e-04   0.80    0.0


Note that the default convergence criterion is on the difference of energy from one step to the other; when this gets below tol, the "driver" self_consistent_field artificially makes the fixpoint solver think it's converged by forcing f(x) = x. You can customize this with the is_converged keyword argument to self_consistent_field.