Arbitrary floating-point types

Since DFTK is completely generic in the floating-point type in its routines, there is no reason to perform the computation using double-precision arithmetic (i.e.Float64). Other floating-point types such as Float32 (single precision) are readily supported as well. On top of that we already reported1 calculations in DFTK using elevated precision from DoubleFloats.jl or interval arithmetic using IntervalArithmetic.jl. In this example, however, we will concentrate on single-precision computations with Float32.

The setup of such a reduced-precision calculation is basically identical to the regular case, since Julia automatically compiles all routines of DFTK at the precision, which is used for the lattice vectors. Apart from setting up the model with an explicit cast of the lattice vectors to Float32, there is thus no change in user code required:


  1. M. F. Herbst, A. Levitt, E. Cancès. A posteriori error estimation for the non-self-consistent Kohn-Sham equations ArXiv 2004.13549

In [1]:
using DFTK

# Setup silicon lattice
a = 10.263141334305942  # lattice constant in Bohr
lattice = a / 2 .* [[0 1 1.]; [1 0 1.]; [1 1 0.]]
Si = ElementPsp(:Si, psp=load_psp(:Si, functional="lda"))
atoms = [Si => [ones(3)/8, -ones(3)/8]]

# Cast to Float32, setup model and basis
model = model_DFT(Array{Float32}(lattice), atoms, [:lda_x, :lda_c_vwn])
basis = PlaneWaveBasis(model, Ecut=7, kgrid=[4, 4, 4])

# Run the SCF
scfres = self_consistent_field(basis, tol=1e-4);
n     Energy            Eₙ-Eₙ₋₁     ρout-ρin   α      Diag
---   ---------------   ---------   --------   ----   ----
  1   -7.907551765442         NaN   1.95e-01   0.80    4.0
  2   -7.912185192108   -4.63e-03   2.99e-02   0.80    1.0
  3   -7.912420272827   -2.35e-04   3.04e-03   0.80    3.0
  4   -7.912420272827    0.00e+00   4.66e-04   0.80    2.4

To check the calculation has really run in Float32, we check the energies and density are expressed in this floating-point type:

In [2]:
scfres.energies
Out[2]:
Energy breakdown (in Ha):
    Kinetic             3.0800195 
    AtomicLocal         -2.1816478
    AtomicNonlocal      1.7341535 
    Ewald               -8.3978930
    PspCorrection       -0.2946220
    Hartree             0.5421669 
    Xc                  -2.3945980

    total               -7.912420272827
In [3]:
eltype(scfres.energies.total)
Out[3]:
Float32
In [4]:
eltype(scfres.ρ)
Out[4]:
Float32

!!! note "Generic linear algebra routines" For more unusual floating-point types (like IntervalArithmetic or DoubleFloats), which are not directly supported in the standard LinearAlgebra library of Julia one additional step is required: One needs to explicitly enable the generic versions of standard linear-algebra operations like cholesky or qr, which are needed inside DFTK by loading the GenericLinearAlgebra package in the user script (i.e. just add ad using GenericLinearAlgebra next to your using DFTK call).