Collinear spin and magnetic systems

In this example we consider iron in the BCC phase. To show that this material is ferromagnetic we will model it once allowing collinear spin polarization and once without and compare the resulting SCF energies. In particular the ground state can only be found if collinear spins are allowed.

First we setup BCC iron without spin polarization using a single iron atom inside the unit cell.

In [1]:
using DFTK

a = 5.42352  # Bohr
lattice = a / 2 * [[-1  1  1];
                   [ 1 -1  1];
                   [ 1  1 -1]]
atoms     = [ElementPsp(:Fe, psp=load_psp("hgh/lda/Fe-q8.hgh"))]
positions = [zeros(3)];

To get the ground-state energy we use an LDA model and rather moderate discretisation parameters.

In [2]:
kgrid = [3, 3, 3]  # k-point grid (Regular Monkhorst-Pack grid)
Ecut = 15          # kinetic energy cutoff in Hartree
model_nospin = model_LDA(lattice, atoms, positions, temperature=0.01)
basis_nospin = PlaneWaveBasis(model_nospin; kgrid, Ecut)

scfres_nospin = self_consistent_field(basis_nospin; tol=1e-6, mixing=KerkerDosMixing());
n     Energy            log10(ΔE)   log10(Δρ)   Diag
---   ---------------   ---------   ---------   ----
  1   -16.65001142199                   -0.48    5.2
  2   -16.65070728131       -3.16       -1.01    1.0
  3   -16.65081001993       -3.99       -2.32    1.5
  4   -16.65082418049       -4.85       -2.82    3.0
  5   -16.65082465573       -6.32       -3.28    2.0
In [3]:
scfres_nospin.energies
Out[3]:
Energy breakdown (in Ha):
    Kinetic             15.9189324
    AtomicLocal         -5.0682667
    AtomicNonlocal      -5.2191676
    Ewald               -21.4723040
    PspCorrection       1.8758831 
    Hartree             0.7790318 
    Xc                  -3.4466465
    Entropy             -0.0182871

    total               -16.650824655726

Since we did not specify any initial magnetic moment on the iron atom, DFTK will automatically assume that a calculation with only spin-paired electrons should be performed. As a result the obtained ground state features no spin-polarization.

Now we repeat the calculation, but give the iron atom an initial magnetic moment. For specifying the magnetic moment pass the desired excess of spin-up over spin-down electrons at each centre to the Model and the guess density functions. In this case we seek the state with as many spin-parallel $d$-electrons as possible. In our pseudopotential model the 8 valence electrons are 2 pair of $s$-electrons, 1 pair of $d$-electrons and 4 unpaired $d$-electrons giving a desired magnetic moment of 4 at the iron centre. The structure (i.e. pair mapping and order) of the magnetic_moments array needs to agree with the atoms array and 0 magnetic moments need to be specified as well.

In [4]:
magnetic_moments = [4];

!!! tip "Units of the magnetisation and magnetic moments in DFTK" Unlike all other quantities magnetisation and magnetic moments in DFTK are given in units of the Bohr magneton $μ_B$, which in atomic units has the value $\frac{1}{2}$. Since $μ_B$ is (roughly) the magnetic moment of a single electron the advantage is that one can directly think of these quantities as the excess of spin-up electrons or spin-up electron density.

We repeat the calculation using the same model as before. DFTK now detects the non-zero moment and switches to a collinear calculation.

In [5]:
model = model_LDA(lattice, atoms, positions; magnetic_moments, temperature=0.01)
basis = PlaneWaveBasis(model; Ecut, kgrid)
ρ0 = guess_density(basis, magnetic_moments)
scfres = self_consistent_field(basis, tol=1e-6; ρ=ρ0, mixing=KerkerDosMixing());
n     Energy            log10(ΔE)   log10(Δρ)   Magnet   Diag
---   ---------------   ---------   ---------   ------   ----
  1   -16.66160009422                   -0.51    2.618    5.1
  2   -16.66808536456       -2.19       -1.09    2.445    1.4
  3   -16.66905479463       -3.01       -2.05    2.337    2.4
  4   -16.66910020976       -4.34       -2.73    2.303    2.1
  5   -16.66910298289       -5.56       -2.92    2.296    2.5
  6   -16.66910443068       -5.84       -3.49    2.286    2.4
  7   -16.66910445791       -7.56       -3.79    2.286    1.9
In [6]:
scfres.energies
Out[6]:
Energy breakdown (in Ha):
    Kinetic             16.2945304
    AtomicLocal         -5.2225831
    AtomicNonlocal      -5.4099193
    Ewald               -21.4723040
    PspCorrection       1.8758831 
    Hartree             0.8191521 
    Xc                  -3.5407048
    Entropy             -0.0131588

    total               -16.669104457907

!!! note "Model and magnetic moments" DFTK does not store the magnetic_moments inside the Model, but only uses them to determine the lattice symmetries. This step was taken to keep Model (which contains the physical model) independent of the details of the numerical details such as the initial guess for the spin density.

In direct comparison we notice the first, spin-paired calculation to be a little higher in energy

In [7]:
println("No magnetization: ", scfres_nospin.energies.total)
println("Magnetic case:    ", scfres.energies.total)
println("Difference:       ", scfres.energies.total - scfres_nospin.energies.total);
No magnetization: -16.65082465572561
Magnetic case:    -16.669104457906602
Difference:       -0.018279802180991567

Notice that with the small cutoffs we use to generate the online documentation the calculation is far from converged. With more realistic parameters a larger energy difference of about 0.1 Hartree is obtained.

The spin polarization in the magnetic case is visible if we consider the occupation of the spin-up and spin-down Kohn-Sham orbitals. Especially for the $d$-orbitals these differ rather drastically. For example for the first $k$-point:

In [8]:
iup   = 1
idown = iup + length(scfres.basis.kpoints) ÷ 2
@show scfres.occupation[iup][1:7]
@show scfres.occupation[idown][1:7];
(scfres.occupation[iup])[1:7] = [1.0, 0.9999987825149347, 0.9999987825149458, 0.9999987825149427, 0.958240834036178, 0.9582408340120638, 1.1234988115247087e-29]
(scfres.occupation[idown])[1:7] = [1.0, 0.843307534541922, 0.8433075344678751, 0.8433075343977238, 8.09668898268205e-6, 8.096688998944695e-6, 1.598818790556491e-32]

Similarly the eigenvalues differ

In [9]:
@show scfres.eigenvalues[iup][1:7]
@show scfres.eigenvalues[idown][1:7];
(scfres.eigenvalues[iup])[1:7] = [-0.06936343562401778, 0.35687798387841396, 0.35687798378638347, 0.35687798381162206, 0.46173340251408024, 0.4617334025201065, 1.159650403610805]
(scfres.eigenvalues[idown])[1:7] = [-0.03125821950512617, 0.47623473783545217, 0.47623473784105586, 0.4762347378463647, 0.6103056766976542, 0.6103056766775685, 1.2251997829417396]

!!! note "$k$-points in collinear calculations" For collinear calculations the kpoints field of the PlaneWaveBasis object contains each $k$-point coordinate twice, once associated with spin-up and once with down-down. The list first contains all spin-up $k$-points and then all spin-down $k$-points, such that iup and idown index the same $k$-point, but differing spins.

We can observe the spin-polarization by looking at the density of states (DOS) around the Fermi level, where the spin-up and spin-down DOS differ.

In [10]:
using Plots
plot_dos(scfres)
Out[10]:

Similarly the band structure shows clear differences between both spin components.

In [11]:
using Unitful
using UnitfulAtomic
plot_bandstructure(scfres; kline_density=6)
Computing bands along kpath:
       Γ -> H -> N -> Γ -> P -> H  and  P -> N
Diagonalising Hamiltonian kblocks: 100%|████████████████| Time: 0:00:01
Out[11]: