# Custom solvers¶

In this example, we show how to define custom solvers. Our system will again be silicon, because we are not very imaginative

In :
using DFTK, LinearAlgebra

a = 10.26
lattice = a / 2 * [[0 1 1.];
[1 0 1.];
[1 1 0.]]
atoms = [Si, Si]
positions =  [ones(3)/8, -ones(3)/8]

# We take very (very) crude parameters
model = model_LDA(lattice, atoms, positions)
basis = PlaneWaveBasis(model; Ecut=5, kgrid=[1, 1, 1]);


We define our custom fix-point solver: simply a damped fixed-point

In :
function my_fp_solver(f, x0, max_iter; tol)
mixing_factor = .7
x = x0
fx = f(x)
for n = 1:max_iter
inc = fx - x
if norm(inc) < tol
break
end
x = x + mixing_factor * inc
fx = f(x)
end
(fixpoint=x, converged=norm(fx-x) < tol)
end;


Our eigenvalue solver just forms the dense matrix and diagonalizes it explicitly (this only works for very small systems)

In :
function my_eig_solver(A, X0; maxiter, tol, kwargs...)
n = size(X0, 2)
A = Array(A)
E = eigen(A)
λ = E.values[1:n]
X = E.vectors[:, 1:n]
(λ=λ, X=X, residual_norms=[], iterations=0, converged=true, n_matvec=0)
end;


Finally we also define our custom mixing scheme. It will be a mixture of simple mixing (for the first 2 steps) and than default to Kerker mixing. In the mixing interface δF is (ρ_\text{out} - ρ_\text{in}), i.e. the difference in density between two subsequent SCF steps and the mix function returns δρ, which is added to ρ_\text{in} to yield ρ_\text{next}, the density for the next SCF step.

In :
struct MyMixing
n_simple  # Number of iterations for simple mixing
end
MyMixing() = MyMixing(2)

function DFTK.mix_density(mixing::MyMixing, basis, δF; n_iter, kwargs...)
if n_iter <= mixing.n_simple
return δF  # Simple mixing -> Do not modify update at all
else
# Use the default KerkerMixing from DFTK
DFTK.mix_density(KerkerMixing(), basis, δF; kwargs...)
end
end


That's it! Now we just run the SCF with these solvers

In :
scfres = self_consistent_field(basis;
tol=1e-8,
solver=my_fp_solver,
eigensolver=my_eig_solver,
mixing=MyMixing());

n     Energy            log10(ΔE)   log10(Δρ)   Diag
---   ---------------   ---------   ---------   ----
1   -7.236023732203                   -0.50    0.0
2   -7.249611449036       -1.87       -0.92    0.0
3   -7.251175102701       -2.81       -1.34    0.0
4   -7.251296007223       -3.92       -1.65    0.0
5   -7.251327328326       -4.50       -1.96    0.0
6   -7.251335597614       -5.08       -2.25    0.0
7   -7.251337862375       -5.64       -2.54    0.0
8   -7.251338511713       -6.19       -2.83    0.0
9   -7.251338707003       -6.71       -3.10    0.0
10   -7.251338768389       -7.21       -3.37    0.0
11   -7.251338788417       -7.70       -3.62    0.0
12   -7.251338795146       -8.17       -3.87    0.0


Note that the default convergence criterion is on the difference of energy from one step to the other; when this gets below tol, the "driver" self_consistent_field artificially makes the fixpoint solver think it's converged by forcing f(x) = x. You can customize this with the is_converged keyword argument to self_consistent_field.