# Polarizability using automatic differentiation¶

Simple example for computing properties using (forward-mode) automatic differentation. For a more classical approach and more details about computing polarizabilities, see Polarizability by linear response.

In :
using DFTK
using LinearAlgebra
using ForwardDiff

# Construct PlaneWaveBasis given a particular electric field strength
# Again we take the example of a Helium atom.
function make_basis(ε::T; a=10., Ecut=30) where {T}
lattice=T(a) * I(3)  # lattice is a cube of $a$ Bohrs
# Helium at the center of the box
atoms     = [ElementPsp(:He, psp=load_psp("hgh/lda/He-q2"))]
positions = [[1/2, 1/2, 1/2]]

model = model_DFT(lattice, atoms, positions, [:lda_x, :lda_c_vwn];
extra_terms=[ExternalFromReal(r -> -ε * (r - a/2))],
symmetries=false)
PlaneWaveBasis(model; Ecut, kgrid=[1, 1, 1])  # No k-point sampling on isolated system
end

# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
@assert isdiag(basis.model.lattice)
a  = basis.model.lattice[1, 1]
rr = [a * (r - 1/2) for r in r_vectors(basis)]
sum(rr .* ρ) * basis.dvol
end

# Function to compute the dipole for a given field strength
function compute_dipole(ε; tol=1e-8, kwargs...)
scfres = self_consistent_field(make_basis(ε; kwargs...), tol=tol)
dipole(scfres.basis, scfres.ρ)
end;


With this in place we can compute the polarizability from finite differences (just like in the previous example):

In :
polarizability_fd = let
ε = 0.01
(compute_dipole(ε) - compute_dipole(0.0)) / ε
end

n     Energy            log10(ΔE)   log10(Δρ)   Diag
---   ---------------   ---------   ---------   ----
1   -2.770931786396                   -0.53    8.0
2   -2.772140215953       -2.92       -1.31    1.0
3   -2.772169900537       -4.53       -2.60    1.0
4   -2.772170720443       -6.09       -4.04    2.0
5   -2.772170722864       -8.62       -4.45    3.0
n     Energy            log10(ΔE)   log10(Δρ)   Diag
---   ---------------   ---------   ---------   ----
1   -2.770670630184                   -0.53    8.0
2   -2.772045586983       -2.86       -1.30    1.0
3   -2.772083338565       -4.42       -2.63    2.0
4   -2.772083417191       -7.10       -4.29    2.0
5   -2.772083417789       -9.22       -4.81    3.0

Out:
1.7735443819964194

We do the same thing using automatic differentiation. Under the hood this uses custom rules to implicitly differentiate through the self-consistent field fixed-point problem.

In :
polarizability = ForwardDiff.derivative(compute_dipole, 0.0)
println()
println("Polarizability via ForwardDiff:       $polarizability") println("Polarizability via finite difference:$polarizability_fd")

n     Energy            log10(ΔE)   log10(Δρ)   Diag
---   ---------------   ---------   ---------   ----
1   -2.770472079056                   -0.53    8.0
2   -2.772037126990       -2.81       -1.29    1.0
3   -2.772083276556       -4.34       -2.92    2.0
4   -2.772083416523       -6.85       -3.67    2.0
5   -2.772083417794       -8.90       -4.44    2.0

Polarizability via ForwardDiff:       1.7725694164554262
Polarizability via finite difference: 1.7735443819964194