Temperature and metallic systems

In this example we consider the modeling of a magnesium lattice as a simple example for a metallic system. For our treatment we will use the PBE exchange-correlation functional. First we import required packages and setup the lattice. Again notice that DFTK uses the convention that lattice vectors are specified column by column.

In [1]:
using DFTK
using Plots
using Unitful
using UnitfulAtomic

a = 3.01794  # bohr
b = 5.22722  # bohr
c = 9.77362  # bohr
lattice = [[-a -a  0]; [-b  b  0]; [0   0 -c]]
Mg = ElementPsp(:Mg, psp=load_psp("hgh/pbe/Mg-q2"))
atoms     = [Mg, Mg]
positions = [[2/3, 1/3, 1/4], [1/3, 2/3, 3/4]];

Next we build the PBE model and discretize it. Since magnesium is a metal we apply a small smearing temperature to ease convergence using the Fermi-Dirac smearing scheme. Note that both the Ecut is too small as well as the minimal $k$-point spacing kspacing far too large to give a converged result. These have been selected to obtain a fast execution time. By default PlaneWaveBasis chooses a kspacing of 2π * 0.022 inverse Bohrs, which is much more reasonable.

In [2]:
kspacing = 0.945 / u"angstrom"        # Minimal spacing of k-points,
#                                      in units of wavevectors (inverse Bohrs)
Ecut = 5                              # Kinetic energy cutoff in Hartree
temperature = 0.01                    # Smearing temperature in Hartree
smearing = DFTK.Smearing.FermiDirac() # Smearing method
#                                      also supported: Gaussian,
#                                      MarzariVanderbilt,
#                                      and MethfesselPaxton(order)

model = model_DFT(lattice, atoms, positions, [:gga_x_pbe, :gga_c_pbe];
                  temperature, smearing)
kgrid = kgrid_from_minimal_spacing(lattice, kspacing)
basis = PlaneWaveBasis(model; Ecut, kgrid);

Finally we run the SCF. Two magnesium atoms in our pseudopotential model result in four valence electrons being explicitly treated. Nevertheless this SCF will solve for eight bands by default in order to capture partial occupations beyond the Fermi level due to the employed smearing scheme. In this example we use a damping of 0.8. The default LdosMixing should be suitable to converge metallic systems like the one we model here. For the sake of demonstration we still switch to Kerker mixing here.

In [3]:
scfres = self_consistent_field(basis, damping=0.8, mixing=KerkerMixing());
n     Energy            log10(ΔE)   log10(Δρ)   Diag
---   ---------------   ---------   ---------   ----
  1   -1.743183754299                   -1.28    4.7
  2   -1.743516316428       -3.48       -1.70    1.0
  3   -1.743614816216       -4.01       -2.86    4.0
  4   -1.743616748717       -5.71       -3.62    3.8
  5   -1.743616766330       -7.75       -4.67    3.2
In [4]:
scfres.occupation[1]
Out[4]:
9-element Vector{Float64}:
 1.9999999999941416
 1.9985517899815068
 1.9905519198844848
 1.244919411555916e-17
 1.2448341893155876e-17
 1.0291278177927476e-17
 1.0290402174095082e-17
 2.988348619503194e-19
 1.6611654668377806e-21
In [5]:
scfres.energies
Out[5]:
Energy breakdown (in Ha):
    Kinetic             0.7450600 
    AtomicLocal         0.3193213 
    AtomicNonlocal      0.3192758 
    Ewald               -2.1544222
    PspCorrection       -0.1026056
    Hartree             0.0061602 
    Xc                  -0.8615675
    Entropy             -0.0148389

    total               -1.743616766330

The fact that magnesium is a metal is confirmed by plotting the density of states around the Fermi level.

In [6]:
plot_dos(scfres)
Out[6]: