We compute the polarizability of a Helium atom. The polarizability is defined as the change in dipole moment $$ μ = ∫ r ρ(r) dr $$ with respect to a small uniform electric field $E = -x$.
We compute this in two ways: first by finite differences (applying a finite electric field), then by linear response. Note that DFTK is not really adapted to isolated atoms because it uses periodic boundary conditions. Nevertheless we can simply embed the Helium atom in a large enough box (although this is computationally wasteful).
As in other tests, this is not fully converged, convergence parameters were simply selected for fast execution on CI,
using DFTK
using LinearAlgebra
a = 10.
lattice = a * I(3) # cube of $a$ bohrs
# Helium at the center of the box
atoms = [ElementPsp(:He, psp=load_psp("hgh/lda/He-q2"))]
positions = [[1/2, 1/2, 1/2]]
kgrid = [1, 1, 1] # no k-point sampling for an isolated system
Ecut = 30
tol = 1e-8
# dipole moment of a given density (assuming the current geometry)
function dipole(basis, ρ)
rr = [(r[1] - a/2) for r in r_vectors_cart(basis)]
sum(rr .* ρ) * basis.dvol
end;
We first compute the polarizability by finite differences. First compute the dipole moment at rest:
model = model_LDA(lattice, atoms, positions; symmetries=false)
basis = PlaneWaveBasis(model; Ecut, kgrid)
res = self_consistent_field(basis; tol)
μref = dipole(basis, res.ρ)
n Energy log10(ΔE) log10(Δρ) Diag Δtime --- --------------- --------- --------- ---- ------ 1 -2.770314240894 -0.53 9.0 2 -2.771686480165 -2.86 -1.31 1.0 179ms 3 -2.771714203614 -4.56 -2.60 1.0 199ms 4 -2.771714708533 -6.30 -3.74 2.0 194ms 5 -2.771714714662 -8.21 -4.14 2.0 224ms 6 -2.771714715240 -9.24 -5.39 1.0 175ms 7 -2.771714715250 -11.01 -6.35 2.0 219ms 8 -2.771714715250 -13.37 -6.62 1.0 183ms 9 -2.771714715250 + -13.97 -7.45 2.0 217ms 10 -2.771714715250 + -13.71 -7.87 1.0 203ms 11 -2.771714715250 -13.88 -8.72 2.0 210ms
-0.00013457374075714207
Then in a small uniform field:
ε = .01
model_ε = model_LDA(lattice, atoms, positions;
extra_terms=[ExternalFromReal(r -> -ε * (r[1] - a/2))],
symmetries=false)
basis_ε = PlaneWaveBasis(model_ε; Ecut, kgrid)
res_ε = self_consistent_field(basis_ε; tol)
με = dipole(basis_ε, res_ε.ρ)
n Energy log10(ΔE) log10(Δρ) Diag Δtime --- --------------- --------- --------- ---- ------ 1 -2.770559452720 -0.52 9.0 2 -2.771779428612 -2.91 -1.32 1.0 170ms 3 -2.771801736063 -4.65 -2.48 1.0 173ms 4 -2.771802008888 -6.56 -3.19 1.0 215ms 5 -2.771802072488 -7.20 -3.83 2.0 198ms 6 -2.771802074057 -8.80 -4.22 1.0 214ms 7 -2.771802074470 -9.38 -5.48 1.0 181ms 8 -2.771802074476 -11.26 -5.68 2.0 208ms 9 -2.771802074476 -12.32 -6.36 1.0 204ms 10 -2.771802074476 -13.44 -6.78 2.0 221ms 11 -2.771802074476 -14.01 -7.42 1.0 219ms 12 -2.771802074476 + -14.18 -8.46 2.0 212ms
0.017612220961427928
polarizability = (με - μref) / ε
println("Reference dipole: $μref")
println("Displaced dipole: $με")
println("Polarizability : $polarizability")
Reference dipole: -0.00013457374075714207 Displaced dipole: 0.017612220961427928 Polarizability : 1.774679470218507
The result on more converged grids is very close to published results. For example DOI 10.1039/C8CP03569E quotes 1.65 with LSDA and 1.38 with CCSD(T).
Now we use linear response to compute this analytically; we refer to standard textbooks for the formalism. In the following, $χ_0$ is the independent-particle polarizability, and $K$ the Hartree-exchange-correlation kernel. We denote with $δV_{\rm ext}$ an external perturbing potential (like in this case the uniform electric field). Then: $$ δρ = χ_0 δV = χ_0 (δV_{\rm ext} + K δρ), $$ which implies $$ δρ = (1-χ_0 K)^{-1} χ_0 δV_{\rm ext}. $$ From this we identify the polarizability operator to be $χ = (1-χ_0 K)^{-1} χ_0$. Numerically, we apply $χ$ to $δV = -x$ by solving a linear equation (the Dyson equation) iteratively.
using KrylovKit
# Apply $(1- χ_0 K)$
function dielectric_operator(δρ)
δV = apply_kernel(basis, δρ; res.ρ)
χ0δV = apply_χ0(res, δV)
δρ - χ0δV
end
# `δVext` is the potential from a uniform field interacting with the dielectric dipole
# of the density.
δVext = [-(r[1] - a/2) for r in r_vectors_cart(basis)]
δVext = cat(δVext; dims=4)
# Apply $χ_0$ once to get non-interacting dipole
δρ_nointeract = apply_χ0(res, δVext)
# Solve Dyson equation to get interacting dipole
δρ = linsolve(dielectric_operator, δρ_nointeract, verbosity=3)[1]
println("Non-interacting polarizability: $(dipole(basis, δρ_nointeract))")
println("Interacting polarizability: $(dipole(basis, δρ))")
WARNING: using KrylovKit.basis in module ##352 conflicts with an existing identifier. [ Info: GMRES linsolve in iter 1; step 1: normres = 2.493920917997e-01 [ Info: GMRES linsolve in iter 1; step 2: normres = 3.766553442905e-03 [ Info: GMRES linsolve in iter 1; step 3: normres = 2.852760524429e-04 [ Info: GMRES linsolve in iter 1; step 4: normres = 4.694609224209e-06 [ Info: GMRES linsolve in iter 1; step 5: normres = 1.088786726229e-08 [ Info: GMRES linsolve in iter 1; step 6: normres = 6.298133183405e-11 [ Info: GMRES linsolve in iter 1; step 7: normres = 1.358153128482e-12 [ Info: GMRES linsolve in iter 1; finished at step 7: normres = 1.358153128482e-12 [ Info: GMRES linsolve in iter 2; step 1: normres = 8.352937765394e-10 [ Info: GMRES linsolve in iter 2; step 2: normres = 7.344276603291e-11 [ Info: GMRES linsolve in iter 2; step 3: normres = 1.438821538059e-12 [ Info: GMRES linsolve in iter 2; finished at step 3: normres = 1.438821538059e-12 ┌ Info: GMRES linsolve converged at iteration 2, step 3: │ * norm of residual = 1.4388131594274984e-12 └ * number of operations = 12 Non-interacting polarizability: 1.9257125365553103 Interacting polarizability: 1.7736548676140294
As expected, the interacting polarizability matches the finite difference result. The non-interacting polarizability is higher.