# Carter frame in Kerr spacetime¶

This Jupyter/SageMath notebook is relative to the lectures Geometry and physics of black holes.

The corresponding tools have been developed within the SageManifolds project.

NB: a version of SageMath at least equal to 9.1 is required to run this notebook:

In :
version()

Out:
'SageMath version 9.2.beta14, Release Date: 2020-09-30'

First we set up the notebook to display mathematical objects using LaTeX rendering:

In :
%display latex


We ask for running tensor computations in parallel on 8 threads:

In :
Parallelism().set(nproc=8)


## Spacetime manifold¶

We declare the Kerr spacetime (or more precisely the part of it covered by Boyer-Lindquist coordinates) as a 4-dimensional Lorentzian manifold $\mathcal{M}$:

In :
M = Manifold(4, 'M', latex_name=r'\mathcal{M}', structure='Lorentzian')
print(M)

4-dimensional Lorentzian manifold M


We then introduce the standard Boyer-Lindquist coordinates as a chart BL (for Boyer-Lindquist) on $\mathcal{M}$, via the method chart(), the argument of which is a string (delimited by r"..." because of the backslash symbols) expressing the coordinates names, their ranges (the default is $(-\infty,+\infty)$) and their LaTeX symbols:

In :
BL.<t,r,th,ph> = M.chart(r"t r th:(0,pi):\theta ph:(0,2*pi):\phi")
print(BL); BL

Chart (M, (t, r, th, ph))

Out:
In :
BL, BL

Out:

## Metric tensor

The 2 parameters $m$ and $a$ of the Kerr spacetime are declared as symbolic variables:

In :
var('m, a', domain='real')

Out:

We get the (yet undefined) spacetime metric:

In :
g = M.metric()


The metric is set by its components in the coordinate frame associated with Boyer-Lindquist coordinates, which is the current manifold's default frame:

In :
rho2 = r^2 + (a*cos(th))^2
Delta = r^2 -2*m*r + a^2
g[0,0] = -(1-2*m*r/rho2)
g[0,3] = -2*a*m*r*sin(th)^2/rho2
g[1,1], g[2,2] = rho2/Delta, rho2
g[3,3] = (r^2+a^2+2*m*r*(a*sin(th))^2/rho2)*sin(th)^2
g.display()

Out:

A matrix view of the components with respect to the manifold's default vector frame:

In :
g[:]

Out:

The list of the non-vanishing components:

In :
g.display_comp()

Out:

## Carter frame¶

The default vector frame on the spacetime manifold is the coordinate basis associated with Boyer-Lindquist coordinates:

In :
M.default_frame() is BL.frame()

Out:
In :
BL.frame()

Out:

The 4-velocity of the Carter obsever is defined by its components w.r.t. the Boyer-Lindquist frame:

In :
rho = sqrt(rho2)
e0 = M.vector_field([(r^2 + a^2)/(rho*sqrt(Delta)), 0, 0, a/(rho*sqrt(Delta))],
name='eps0', latex_name=r'\varepsilon_0')
e0.display()

Out:

We check that is a unit timelike vector:

In :
g(e0, e0).expr()

Out:

and that it is future-directed, by computing its scalar product with the global null vector $k$, which generates the ingoing principal null geodesics:

In :
k = M.vector_field([(r^2 + a^2)/Delta, -1, 0, a/Delta],
name='k')
k.display()

Out:
In :
g(k, e0).expr()

Out:

The spacelike vectors of the Carter frame:

In :
e1 = M.vector_field([0, sqrt(Delta)/rho, 0, 0],
name='eps1', latex_name=r'\varepsilon_1')
e1.display()

Out:
In :
e2 = M.vector_field([0, 0, 1/rho, 0],
name='eps2', latex_name=r'\varepsilon_2')
e2.display()

Out:
In :
e3 = M.vector_field([a*sin(th)/rho, 0, 0, 1/(rho*sin(th))],
name='eps3', latex_name=r'\varepsilon_3')
e3.display()

Out:
In :
CF = M.vector_frame('eps', [e0, e1, e2, e3], latex_symbol=r'\varepsilon')
CF

Out:
In :
for v in CF:
show(v.display())


Check that the Carter frame is orthonormal:

In :
matrix([[g(u, v).expr() for v in CF] for u in CF])

Out:

### The Carter coframe¶

In :
for f in CF.coframe():
show(f.display())


## 4-acceleration of the Carter observer¶

In :
nabla = g.connection()
print(nabla)

Levi-Civita connection nabla_g associated with the Lorentzian metric g on the 4-dimensional Lorentzian manifold M

In :
A = nabla(e0).contract(e0)  # use A to avoid any confusion with the Kerr parameter a
A.set_name('a')
print(A)

Vector field a on the 4-dimensional Lorentzian manifold M

In :
A.apply_map(factor)  # factor the components for a better display
A.display()

Out:

As a check, we note that the above formula agrees with that given by Eqs. (90)-(91) of O. Semerak, Gen. Relat. Grav. 25, 1041 (1993).

Display in the Carter frame:

In :
A.apply_map(factor, frame=CF, keep_other_components=True)
A.display(CF)

Out:

## 4-rotation of the ZAMO frame¶

We define the rotation operator as $$\Omega_{\rm rot}(v) = \nabla_{\varepsilon_0} v - \Omega_{\rm FW}(v)$$ where $$\Omega_{\rm FW}(v) := (a\cdot v) \varepsilon_0 - (\varepsilon_0\cdot v) a$$ is the Fermi-Walker operator:

In :
def rotation_operator(v):
return nabla(v).contract(e0) - g(A, v)*e0 + g(e0, v)*A


Some check:

In :
rotation_operator(e0) == 0

Out:

Let us evaluate $\Omega_{\rm rot}(\varepsilon_1)$:

In :
De1 = rotation_operator(e1)
De1.apply_map(factor)
De1.display()

Out:
In :
De1.apply_map(factor, frame=CF, keep_other_components=True)
De1.display(CF)

Out:

Let us now evaluate $\Omega_{\rm rot}(\varepsilon_2)$:

In :
De2 = rotation_operator(e2)
De2.apply_map(factor)
De2.display()

Out:
In :
De2.apply_map(factor, frame=CF, keep_other_components=True)
De2.display(CF)

Out:

and finally $\Omega_{\rm rot}(e_3)$:

In :
De3 = rotation_operator(e3)
De3.apply_map(factor)
De3.display()

Out:

Let us enforce further trigonometric simplification:

In :
De3.apply_map(lambda x: x.trig_reduce())
De3.apply_map(lambda x: x.simplify_trig())
De3.apply_map(factor)
De3.display()

Out:
In :
De3.apply_map(factor, frame=CF, keep_other_components=True)
De3.display(CF)

Out:

In the orthonormal frame $(\varepsilon_1, \varepsilon_2, \varepsilon_3)$ of the Carter observer's rest space, the matrix of the operator $\Omega_{\rm rot}$ must be of the type $$\left( \begin{array}{ccc} 0 & - \omega^3 & \omega^3 \ \omega^3 & 0 & -\omega^1 \ - \omega^2 & \omega^1 & 0 \end{array} \right), $$ where the $\omega^i$'s are the components on the 4-rotation vector: $$\omega = \omega^i \varepsilon_i $$

From the above expressions of the $\Omega_{\rm rot}(\varepsilon_i)$'s, we get immediately $\omega^3 = 0$ and we check that

In :
De1[CF, 3] == - De3[CF, 1]

Out:
In :
De2[CF, 3] == - De3[CF, 2]

Out:

Therefore, we get the 4-rotation vector $\omega$ as

In :
omega = - De3[CF, 2]*e1 + De3[CF, 1]*e2
omega.set_name('omega', latex_name=r'\omega')
omega.apply_map(factor)
omega.apply_map(factor, frame=CF, keep_other_components=True)
omega.display(CF)

Out:
In :
omega.display()

Out:

As a check, we note that the above formula agrees with that given by Eq. (93) of O. Semerak, Gen. Relat. Grav. 25, 1041 (1993).

In [ ]: