Timelike orbits in Schwarzschild spacetime

This Jupyter/SageMath worksheet is relative to the lectures Geometry and physics of black holes.

Click here to download the worksheet file (ipynb format). To run it, you must start SageMath with the Jupyter notebook, with the command sage -n jupyter

It uses the integrated_geodesic functionality introduced by Karim Van Aelst in SageMath 8.1, in the framework of the SageManifolds project.

A version of SageMath at least equal to 8.1 is required to run this worksheet:

version()

'SageMath version 8.1, Release Date: 2017-12-07'

%display latex  # LaTeX rendering turned on

We define first the spacetime manifold $M$ and the standard Schwarzschild-Droste coordinates on it:

M = Manifold(4, 'M')
X.<t,r,th,ph> = M.chart(r't r:(0,+oo) th:(0,pi):\theta ph:\phi')
X

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(M,(t, r, {\theta}, {\phi})\right)$$

For graphical purposes, we introduce $\mathbb{R}^3$ and some coordinate map $M\to \mathbb{R}^3$:

R3 = Manifold(3, 'R^3', latex_name=r'\mathbb{R}^3')
X3.<x,y,z> = R3.chart()
to_R3 = M.diff_map(R3, {(X, X3): [r*sin(th)*cos(ph), 
                                  r*sin(th)*sin(ph), r*cos(th)]})
to_R3.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & M & \longrightarrow & \mathbb{R}^3 \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & \left(x, y, z\right) = \left(r \cos\left({\phi}\right) \sin\left({\theta}\right), r \sin\left({\phi}\right) \sin\left({\theta}\right), r \cos\left({\theta}\right)\right) \end{array}$$

Next, we define the Schwarzschild metric:

g = M.lorentzian_metric('g')
m = var('m'); assume(m >= 0)
g[0,0], g[1,1] = -(1-2*m/r), 1/(1-2*m/r)
g[2,2], g[3,3] = r^2, (r*sin(th))^2
g.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}g = \left( \frac{2 \, m}{r} - 1 \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{1}{\frac{2 \, m}{r} - 1} \right) \mathrm{d} r\otimes \mathrm{d} r + r^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + r^{2} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$$

We set the specific conserved energy and angular momentum:

#var('E L', domain='real')
E = 0.973
L = 4.2*m

u = M.vector_field(name='u')
u[0] = E/(1-2*m/r)
u[1] = sqrt(E^2 - (1-2*m/r)*(1+L^2/r^2))
u[3] = L/(r^2*sin(th)^2)
u.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}u = \left( -\frac{0.973000000000000}{\frac{2 \, m}{r} - 1} \right) \frac{\partial}{\partial t } + \left( \sqrt{{\left(\frac{17.6400000000000 \, m^{2}}{r^{2}} + 1\right)} {\left(\frac{2 \, m}{r} - 1\right)} + 0.946729000000000} \right) \frac{\partial}{\partial r } + \frac{4.20000000000000 \, m}{r^{2} \sin\left({\theta}\right)^{2}} \frac{\partial}{\partial {\phi} }$$

g(u,u).display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} g\left(u,u\right):& M & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & -\frac{-35.28 \, m^{3} + 17.64 \, m^{2} r - {\left(-35.28 \, m^{3} + 17.64 \, m^{2} r - 2.0 \, m r^{2} + 1.0 \, r^{3}\right)} \sin\left({\theta}\right)^{2}}{{\left(2 \, m r^{2} - r^{3}\right)} \sin\left({\theta}\right)^{2}} \end{array}$$

Pericenter and apocenter:

eq = (r^3*((1-2/r)*(1+L^2/m^2/r^2) - E^2)).simplify_full()
eq

$$\newcommand{\Bold}[1]{\mathbf{#1}}0.053271 \, r^{3} - 2.0 \, r^{2} + 17.64 \, r - 35.28$$

R.<w> = RR[]
print(R)

Univariate Polynomial Ring in w over Real Field with 53 bits of precision

eqp = R(eq.subs(r=w))
eqp

$$\newcommand{\Bold}[1]{\mathbf{#1}}0.0532710000000001 w^{3} - 2.00000000000000 w^{2} + 17.6400000000000 w - 35.2800000000000$$

roots = sorted(eqp.real_roots())
roots

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[2.85236553627370, 9.05774475732293, 25.6337691154627\right]$$

r_per = roots[1]*m
r_apo = roots[2]*m
r_per, r_apo

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(9.05774475732293 \, m, 25.6337691154627 \, m\right)$$

We pick an initial point and an initial tangent vector:

r0 = r_per
p0 = M.point((0, r0, pi/2, 1e-12), name='p_0')
Tp0 = M.tangent_space(p0) 
u0 = u.at(p0)
u0.set_name('u_0')
print(u0)

Tangent vector u_0 at Point p_0 on the 4-dimensional differentiable manifold M

u0.display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}u_0 = 1.24872547137 \frac{\partial}{\partial t } + \frac{0.0511928294381}{m} \frac{\partial}{\partial {\phi} }$$

Let us check that the scalar square of $u_0$ is $-1$, by means of the metric tensor at $p_0$:

g0 = g.at(p0)
print(g0)

Symmetric bilinear form  g on the Tangent space at Point p_0 on the 4-dimensional differentiable manifold M

The scalar square is indeed equal to $-1$:

g0(u0,u0).simplify_full()

$$\newcommand{\Bold}[1]{\mathbf{#1}}-1.0$$

Check

Let us compute the conserved energy and angular momentum along the geodesic by taking scalar products of the 4-velocity $v_0$ with the Killing vectors $\xi=\frac{\partial}{\partial t}$ and $\eta=\frac{\partial}{\partial t}$:

xi = X.frame()[0]
eta = X.frame()[3]
xi, eta

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\frac{\partial}{\partial t }, \frac{\partial}{\partial {\phi} }\right)$$

xi0 = xi.at(p0)
eta0 = eta.at(p0)
print(xi0)
print(eta0)

Tangent vector d/dt at Point p_0 on the 4-dimensional differentiable manifold M
Tangent vector d/dph at Point p_0 on the 4-dimensional differentiable manifold M

The specific conserved energy $\varepsilon$ is:

- g0(xi0, u0)

$$\newcommand{\Bold}[1]{\mathbf{#1}}0.973$$

while the specific conserved angular momentum $\ell$ is

g0(eta0, u0)

$$\newcommand{\Bold}[1]{\mathbf{#1}}4.2 \, m$$

We declare the geodesic through $p_0$ having $v_0$ as inital vector, denoting by $s$ the affine parameter (proper time):

s = var('s')
geod = M.integrated_geodesic(g, (s, 0, 1500), u0); geod

$$\newcommand{\Bold}[1]{\mathbf{#1}}\mbox{Integrated geodesic in the 4-dimensional differentiable manifold M}$$

We ask for the numerical integration of the geodesic, providing some numerical value for the parameter $m$, and then plot it in terms of the Cartesian chart:

sol = geod.solve(step=4, parameters_values={m: 1})  # numerical integration
interp = geod.interpolate()                 # interpolation of the solution for the plot

graph = geod.plot_integrated(chart=X3, mapping=to_R3, ambient_coords=(x,y), plot_points=500, 
                             thickness=2, label_axes=False)   

graph += circle((0,0), r_per/m, linestyle=':')
graph += circle((0,0), r_apo/m, linestyle=':')
graph += circle((0,0), 2, fill=True, edgecolor='grey', facecolor='grey')
show(graph, aspect_ratio=1, axes_labels=[r'$x/m$', r'$y/m$'])

file_name = "ges_orbit_e{:.3f}_l{:.3f}.pdf".format(float(E), float(L/m))
graph.save(file_name, aspect_ratio=1, axes_labels=[r'$x/m$', r'$y/m$'])
file_name

$$\newcommand{\Bold}[1]{\mathbf{#1}}\verb|ges_orbit_e0.973_l4.200.pdf|$$

Some details about the system solved to get the geodesic:

geod.system(verbose=True)

Geodesic in the 4-dimensional differentiable manifold M equipped with Lorentzian metric g on the 4-dimensional differentiable manifold M, and integrated over the Real interval (0, 1500) as a solution to the following geodesic equations, written with respect to Chart (M, (t, r, th, ph)):

Initial point: Point p_0 on the 4-dimensional differentiable manifold M with coordinates [0, 9.05774475732293*m, 1/2*pi, 1.00000000000000e-12] with respect to Chart (M, (t, r, th, ph))
Initial tangent vector: Tangent vector u_0 at Point p_0 on the 4-dimensional differentiable manifold M with components [1.248725471366881, 0, 0, 0.0511928294380894/m] with respect to Chart (M, (t, r, th, ph))

d(t)/ds = Dt
d(r)/ds = Dr
d(th)/ds = Dth
d(ph)/ds = Dph
d(Dt)/ds = 2*Dr*Dt*m/(2*m*r - r^2)
d(Dr)/ds = -(4*Dth^2*m^2*r^3 - 4*Dth^2*m*r^4 + Dth^2*r^5 - 4*Dt^2*m^3 + 4*Dt^2*m^2*r + (Dr^2 - Dt^2)*m*r^2 + (4*Dph^2*m^2*r^3 - 4*Dph^2*m*r^4 + Dph^2*r^5)*sin(th)^2)/(2*m*r^3 - r^4)
d(Dth)/ds = (Dph^2*r*cos(th)*sin(th) - 2*Dr*Dth)/r
d(Dph)/ds = -2*(Dph*Dth*r*cos(th) + Dph*Dr*sin(th))/(r*sin(th))

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left[\left[\frac{2 \, \mathit{Dr} \mathit{Dt} m}{2 \, m r - r^{2}}, -\frac{4 \, \mathit{Dth}^{2} m^{2} r^{3} - 4 \, \mathit{Dth}^{2} m r^{4} + \mathit{Dth}^{2} r^{5} - 4 \, \mathit{Dt}^{2} m^{3} + 4 \, \mathit{Dt}^{2} m^{2} r + {\left(\mathit{Dr}^{2} - \mathit{Dt}^{2}\right)} m r^{2} + {\left(4 \, \mathit{Dph}^{2} m^{2} r^{3} - 4 \, \mathit{Dph}^{2} m r^{4} + \mathit{Dph}^{2} r^{5}\right)} \sin\left({\theta}\right)^{2}}{2 \, m r^{3} - r^{4}}, \frac{\mathit{Dph}^{2} r \cos\left({\theta}\right) \sin\left({\theta}\right) - 2 \, \mathit{Dr} \mathit{Dth}}{r}, -\frac{2 \, {\left(\mathit{Dph} \mathit{Dth} r \cos\left({\theta}\right) + \mathit{Dph} \mathit{Dr} \sin\left({\theta}\right)\right)}}{r \sin\left({\theta}\right)}\right], u_0, \left(M,(t, r, {\theta}, {\phi})\right)\right]$$

We recognize in the above list the Christoffel symbols of the metric $g$:

g.christoffel_symbols_display()

$$\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{lcl} \Gamma_{ \phantom{\, t} \, t \, r }^{ \, t \phantom{\, t} \phantom{\, r} } & = & -\frac{m}{2 \, m r - r^{2}} \\ \Gamma_{ \phantom{\, r} \, t \, t }^{ \, r \phantom{\, t} \phantom{\, t} } & = & -\frac{2 \, m^{2} - m r}{r^{3}} \\ \Gamma_{ \phantom{\, r} \, r \, r }^{ \, r \phantom{\, r} \phantom{\, r} } & = & \frac{m}{2 \, m r - r^{2}} \\ \Gamma_{ \phantom{\, r} \, {\theta} \, {\theta} }^{ \, r \phantom{\, {\theta}} \phantom{\, {\theta}} } & = & 2 \, m - r \\ \Gamma_{ \phantom{\, r} \, {\phi} \, {\phi} }^{ \, r \phantom{\, {\phi}} \phantom{\, {\phi}} } & = & {\left(2 \, m - r\right)} \sin\left({\theta}\right)^{2} \\ \Gamma_{ \phantom{\, {\theta}} \, r \, {\theta} }^{ \, {\theta} \phantom{\, r} \phantom{\, {\theta}} } & = & \frac{1}{r} \\ \Gamma_{ \phantom{\, {\theta}} \, {\phi} \, {\phi} }^{ \, {\theta} \phantom{\, {\phi}} \phantom{\, {\phi}} } & = & -\cos\left({\theta}\right) \sin\left({\theta}\right) \\ \Gamma_{ \phantom{\, {\phi}} \, r \, {\phi} }^{ \, {\phi} \phantom{\, r} \phantom{\, {\phi}} } & = & \frac{1}{r} \\ \Gamma_{ \phantom{\, {\phi}} \, {\theta} \, {\phi} }^{ \, {\phi} \phantom{\, {\theta}} \phantom{\, {\phi}} } & = & \frac{\cos\left({\theta}\right)}{\sin\left({\theta}\right)} \end{array}$$