5次式の2次式と3次式の積への因数分解の仕方¶

黒木玄

In [1]:

using SymPy

# Override the Base.show definition of SymPy.jl:
# https://github.com/JuliaPy/SymPy.jl/blob/29c5bfd1d10ac53014fa7fef468bc8deccadc2fc/src/types.jl#L87-L105

@eval SymPy function Base.show(io::IO, ::MIME"text/latex", x::SymbolicObject)
    print(io, as_markdown("\\displaystyle " * sympy.latex(x, mode="plain", fold_short_frac=false)))
end
@eval SymPy function Base.show(io::IO, ::MIME"text/latex", x::AbstractArray{Sym})
    function toeqnarray(x::Vector{Sym})
        a = join(["\\displaystyle " * sympy.latex(x[i]) for i in 1:length(x)], "\\\\")
        """\\left[ \\begin{array}{r}$a\\end{array} \\right]"""
    end
    function toeqnarray(x::AbstractArray{Sym,2})
        sz = size(x)
        a = join([join("\\displaystyle " .* map(sympy.latex, x[i,:]), "&") for i in 1:sz[1]], "\\\\")
        "\\left[ \\begin{array}{" * repeat("r",sz[2]) * "}" * a * "\\end{array}\\right]"
    end
    print(io, as_markdown(toeqnarray(x)))
end

In [2]:

all_coeffs(f, x) = sympy.poly(f, x).all_coeffs()

function all_divisors(x)
    @assert x != 0
    A = typeof(x)[]
    for i in 1:abs(x)
        if mod(x, i) == 0
            push!(A, i, -i)
        end
    end
    A
end

function factor_for_all_divisors(f, var, constant_term)
    A = all_divisors(constant_term)
    stack([k, f(var=>k).factor()] for k in A; dims=1)
end

Out[2]:

factor_for_all_divisors (generic function with 1 method)

一般論¶

In [3]:

@vars a b c d e p q r s t u v x

Out[3]:

(a, b, c, d, e, p, q, r, s, t, u, v, x)

$t\ne 0$ と仮定する.

In [4]:

f = x^5 + p*x^4 + q*x^3 + r*x^2 + s*x + t

Out[4]:

$\displaystyle p x^{4} + q x^{3} + r x^{2} + s x + t + x^{5}$

In [5]:

g = x^2 + a*x + b

Out[5]:

$\displaystyle a x + b + x^{2}$

In [6]:

h = x^3 + c*x^2 + d*x + e

Out[6]:

$\displaystyle c x^{2} + d x + e + x^{3}$

$f$ を $g$ で割ったときの商と余りを求める.

In [7]:

quotient, remainder = sympy.div(f, g, x)
sympy.poly.([quotient, remainder], x)

Out[7]:

$\left[ \begin{array}{r}\displaystyle \operatorname{Poly}{\left( x^{3} + \left(- a + p\right) x^{2} + \left(a^{2} - a p - b + q\right) x - a^{3} + a^{2} p + 2 a b - a q - b p + r, x, domain=\mathbb{Z}\left[p, q, r, a, b\right] \right)}\\\displaystyle \operatorname{Poly}{\left( \left(a^{4} - a^{3} p - 3 a^{2} b + a^{2} q + 2 a b p - a r + b^{2} - b q + s\right) x + a^{3} b - a^{2} b p - 2 a b^{2} + a b q + b^{2} p - b r + t, x, domain=\mathbb{Z}\left[p, q, r, s, t, a, b\right] \right)}\end{array} \right]$

$h$ が商に一致することと $c,d,e$ が次のようになることは同値.

In [8]:

_, C, D, E = all_coeffs(quotient, x)

Out[8]:

$\left[ \begin{array}{r}\displaystyle 1\\\displaystyle - a + p\\\displaystyle a^{2} - a p - b + q\\\displaystyle - a^{3} + a^{2} p + 2 a b - a q - b p + r\end{array} \right]$

$be = t\ne 0$ ならば $b\ne 0$ でなければいけない.

そのとき, 余りが0になることと以下の2つが0になることは同値である.

In [9]:

eqrem0 = remainder.coeff(x, 0)/b |> expand

Out[9]:

$\displaystyle a^{3} - a^{2} p - 2 a b + a q + b p - r + \frac{t}{b}$

In [10]:

eqrem1 = remainder.coeff(x, 1)

Out[10]:

$\displaystyle a^{4} - a^{3} p - 3 a^{2} b + a^{2} q + 2 a b p - a r + b^{2} - b q + s$

与えられた5次でモニックな整数係数多項式 $f$ の整数係数の2次式 $g$ と3次式 $h$ の積への分解を求めるためには, まず $be=t$ を満たす整数の組 $(b, e)$ の各々について, eqrem0 を0にする整数 $a$ が存在するかどうかを確認し, 存在する場合に eqrem1 が0になるかどうかも確認し, eqrem0 と eqrem1 の両方を $0$ にするような整数の組 $(a,b)$ を見付ければよい. (見付からない場合には整数係数の2次式と整数係数の3次式の積に分解不可能なことが証明されたことになる.)

雑多な計算メモ¶

In [11]:

sympy.div(f, x^3 + a*x^2 + b*x + c, x) |> collect

Out[11]:

$\left[ \begin{array}{r}\displaystyle a^{2} - a p - b + q + x^{2} + x \left(- a + p\right)\\\displaystyle - a^{2} c + a c p + b c - c q + t + x^{2} \left(- a^{3} + a^{2} p + 2 a b - a q - b p - c + r\right) + x \left(- a^{2} b + a b p + a c + b^{2} - b q - c p + s\right)\end{array} \right]$

In [12]:

sympy.div(x^6 + p*x^5 + q*x^4 + r*x^3 + s*x^2 + t*x + u, g, x) |> collect

Out[12]:

$\left[ \begin{array}{r}\displaystyle a^{4} - a^{3} p - 3 a^{2} b + a^{2} q + 2 a b p - a r + b^{2} - b q + s + x^{4} + x^{3} \left(- a + p\right) + x^{2} \left(a^{2} - a p - b + q\right) + x \left(- a^{3} + a^{2} p + 2 a b - a q - b p + r\right)\\\displaystyle - a^{4} b + a^{3} b p + 3 a^{2} b^{2} - a^{2} b q - 2 a b^{2} p + a b r - b^{3} + b^{2} q - b s + u + x \left(- a^{5} + a^{4} p + 4 a^{3} b - a^{3} q - 3 a^{2} b p + a^{2} r - 3 a b^{2} + 2 a b q - a s + b^{2} p - b r + t\right)\end{array} \right]$

In [13]:

Q63, R63 = sympy.div(x^6 + p*x^5 + q*x^4 + r*x^3 + s*x^2 + t*x + u, x^3 + a*x^2 + b*x + c, x) |> collect

Out[13]:

$\left[ \begin{array}{r}\displaystyle - a^{3} + a^{2} p + 2 a b - a q - b p - c + r + x^{3} + x^{2} \left(- a + p\right) + x \left(a^{2} - a p - b + q\right)\\\displaystyle a^{3} c - a^{2} c p - 2 a b c + a c q + b c p + c^{2} - c r + u + x^{2} \left(a^{4} - a^{3} p - 3 a^{2} b + a^{2} q + 2 a b p + 2 a c - a r + b^{2} - b q - c p + s\right) + x \left(a^{3} b - a^{2} b p - a^{2} c - 2 a b^{2} + a b q + a c p + b^{2} p + 2 b c - b r - c q + t\right)\end{array} \right]$

In [14]:

C63 = all_coeffs(R63, x)

Out[14]:

$\left[ \begin{array}{r}\displaystyle a^{4} - a^{3} p - 3 a^{2} b + a^{2} q + 2 a b p + 2 a c - a r + b^{2} - b q - c p + s\\\displaystyle a^{3} b - a^{2} b p - a^{2} c - 2 a b^{2} + a b q + a c p + b^{2} p + 2 b c - b r - c q + t\\\displaystyle a^{3} c - a^{2} c p - 2 a b c + a c q + b c p + c^{2} - c r + u\end{array} \right]$

In [15]:

B63 = sympy.solve(C63[end], b)[end]

Out[15]:

$\displaystyle \frac{a^{3} c - a^{2} c p + a c q + c^{2} - c r + u}{c \left(2 a - p\right)}$

In [16]:

@show eqrem63_1 = -(C63[1](b=>B63)(u=>c*v) * (-2*a + p)^2).expand().factor();

eqrem63_1 = -(((((C63[1])(b => B63))(u => c * v) * (-2a + p) ^ 2).expand()).factor()) = a^6 - 3*a^5*p + 3*a^4*p^2 + 2*a^4*q - 4*a^3*c - a^3*p^3 - 4*a^3*p*q + 4*a^3*v + 7*a^2*c*p + 2*a^2*p^2*q + a^2*p*r - 5*a^2*p*v + a^2*q^2 - 4*a^2*s - 4*a*c*p^2 - a*p^2*r + 2*a*p^2*v - a*p*q^2 + 4*a*p*s - c^2 + c*p^3 - c*p*q + 2*c*r - 2*c*v - p^2*s + p*q*r - p*q*v - r^2 + 2*r*v - v^2

In [17]:

all_coeffs(eqrem63_1, a)

Out[17]:

$\left[ \begin{array}{r}\displaystyle 1\\\displaystyle - 3 p\\\displaystyle 3 p^{2} + 2 q\\\displaystyle - 4 c - p^{3} - 4 p q + 4 v\\\displaystyle 7 c p + 2 p^{2} q + p r - 5 p v + q^{2} - 4 s\\\displaystyle - 4 c p^{2} - p^{2} r + 2 p^{2} v - p q^{2} + 4 p s\\\displaystyle - c^{2} + c p^{3} - c p q + 2 c r - 2 c v - p^{2} s + p q r - p q v - r^{2} + 2 r v - v^{2}\end{array} \right]$

In [18]:

Problems = [
    x^5 + x + 1
    x^5 - 5x + 3
    x^5 + x + 6
    x^5 - x + 15
    x^5 - 9x - 27
    x^5 - 9x + 27
    x^5 - 5x + 28
    x^5 + 16x + 32
    x^5 + 16x - 32
    x^5 - 5x^2 + 2
    x^5 - x^2 + 4
    x^5 + 2x^2 + 4
    x^5 - 3x^2 + 18
    x^5 + x^2 + 18
]

stack([f, f.factor()] for f in Problems; dims=1)

Out[18]:

$\left[ \begin{array}{rr}\displaystyle x^{5} + x + 1&\displaystyle \left(x^{2} + x + 1\right) \left(x^{3} - x^{2} + 1\right)\\\displaystyle x^{5} - 5 x + 3&\displaystyle \left(x^{2} + x - 1\right) \left(x^{3} - x^{2} + 2 x - 3\right)\\\displaystyle x^{5} + x + 6&\displaystyle \left(x^{2} + x + 2\right) \left(x^{3} - x^{2} - x + 3\right)\\\displaystyle x^{5} - x + 15&\displaystyle \left(x^{2} + x + 3\right) \left(x^{3} - x^{2} - 2 x + 5\right)\\\displaystyle x^{5} - 9 x - 27&\displaystyle \left(x^{2} + 3 x + 3\right) \left(x^{3} - 3 x^{2} + 6 x - 9\right)\\\displaystyle x^{5} - 9 x + 27&\displaystyle \left(x^{2} - 3 x + 3\right) \left(x^{3} + 3 x^{2} + 6 x + 9\right)\\\displaystyle x^{5} - 5 x + 28&\displaystyle \left(x^{2} + x + 4\right) \left(x^{3} - x^{2} - 3 x + 7\right)\\\displaystyle x^{5} + 16 x + 32&\displaystyle \left(x^{2} + 2 x + 4\right) \left(x^{3} - 2 x^{2} + 8\right)\\\displaystyle x^{5} + 16 x - 32&\displaystyle \left(x^{2} - 2 x + 4\right) \left(x^{3} + 2 x^{2} - 8\right)\\\displaystyle x^{5} - 5 x^{2} + 2&\displaystyle \left(x^{2} - x - 1\right) \left(x^{3} + x^{2} + 2 x - 2\right)\\\displaystyle x^{5} - x^{2} + 4&\displaystyle \left(x^{2} + x + 2\right) \left(x^{3} - x^{2} - x + 2\right)\\\displaystyle x^{5} + 2 x^{2} + 4&\displaystyle \left(x^{2} - 2 x + 2\right) \left(x^{3} + 2 x^{2} + 2 x + 2\right)\\\displaystyle x^{5} - 3 x^{2} + 18&\displaystyle \left(x^{2} - 3 x + 3\right) \left(x^{3} + 3 x^{2} + 6 x + 6\right)\\\displaystyle x^{5} + x^{2} + 18&\displaystyle \left(x^{2} + x + 3\right) \left(x^{3} - x^{2} - 2 x + 6\right)\end{array}\right]$

例1¶

$g = x^2 + 3x - 2$, $h = (x+1)^3-2 = x^3+3x^2+3x-1$ の場合にどうなるか.

In [19]:

GG = x^2 + 3x - 2

Out[19]:

$\displaystyle x^{2} + 3 x - 2$

In [20]:

HH = (x+1)^3-2 |> expand

Out[20]:

$\displaystyle x^{3} + 3 x^{2} + 3 x - 1$

In [21]:

FF = GG*HH

Out[21]:

$\displaystyle \left(x^{2} + 3 x - 2\right) \left(x^{3} + 3 x^{2} + 3 x - 1\right)$

In [22]:

FF = expand(FF)

Out[22]:

$\displaystyle x^{5} + 6 x^{4} + 10 x^{3} + 2 x^{2} - 9 x + 2$

既存の函数を使えば因数分解は易しい.

In [23]:

factor(FF)

Out[23]:

$\displaystyle \left(x^{2} + 3 x - 2\right) \left(x^{3} + 3 x^{2} + 3 x - 1\right)$

係数を $P,Q,R,S,T$ に代入する.

In [24]:

_, P, Q, R, S, T = all_coeffs(FF, x)

Out[24]:

$\left[ \begin{array}{r}\displaystyle 1\\\displaystyle 6\\\displaystyle 10\\\displaystyle 2\\\displaystyle -9\\\displaystyle 2\end{array} \right]$

余りの定数項が0になるという条件.

In [25]:

Eqrem0 = eqrem0(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[25]:

$\displaystyle a^{3} - 6 a^{2} - 2 a b + 10 a + 6 b - 2 + \frac{2}{b}$

余りの1次の項が0になるという条件.

In [26]:

Eqrem1 = eqrem1(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[26]:

$\displaystyle a^{4} - 6 a^{3} - 3 a^{2} b + 10 a^{2} + 12 a b - 2 a + b^{2} - 10 b - 9$

$be = 2$ となる整数の組 $(b, e)$ 全体について, 最下段の方程式が整数解を持つ場合を探す.

In [27]:

factor_for_all_divisors(Eqrem0, b, N(T))

Out[27]:

$\left[ \begin{array}{rr}\displaystyle 1&\displaystyle a^{3} - 6 a^{2} + 8 a + 6\\\displaystyle -1&\displaystyle a^{3} - 6 a^{2} + 12 a - 10\\\displaystyle 2&\displaystyle a^{3} - 6 a^{2} + 6 a + 11\\\displaystyle -2&\displaystyle \left(a - 3\right) \left(a^{2} - 3 a + 5\right)\end{array}\right]$

最後の $b=-2$ の場合にのみ整数解 $a=3$ が存在することがわかった.

In [28]:

BB, AA = -2, 3

Out[28]:

(-2, 3)

この場合が実際に解になっていることの確認.

In [29]:

C, D, E

Out[29]:

(-a + p, a^2 - a*p - b + q, -a^3 + a^2*p + 2*a*b - a*q - b*p + r)

In [30]:

CC, DD, EE = C(a=>AA, b=>BB, p=>P), D(a=>AA, b=>BB, p=>P, q=>Q), E(a=>AA, b=>BB, p=>P, q=>Q, r=>R, t=>T)

Out[30]:

(3, 3, -1)

In [31]:

Eqrem1(a=>AA, b=>BB)

Out[31]:

$\displaystyle 0$

In [32]:

sol = (x^2 + AA*x + BB)*(x^3 + CC*x^2 + DD*x + EE)

Out[32]:

$\displaystyle \left(x^{2} + 3 x - 2\right) \left(x^{3} + 3 x^{2} + 3 x - 1\right)$

In [33]:

sol - FF |> simplify

Out[33]:

$\displaystyle 0$

例2¶

$f = x^5 - x^4 - 1$ の因数分解.

In [34]:

FF = x^5 - x^4 - 1

Out[34]:

$\displaystyle x^{5} - x^{4} - 1$

既存の函数を使えば易しい.

In [35]:

factor(FF)

Out[35]:

$\displaystyle \left(x^{2} - x + 1\right) \left(x^{3} - x - 1\right)$

よくある解答例では天下り的に「$x^3$ を足して引く」という方法を使っている.

$$ \begin{aligned} x^5 - x^4 - 1 &= x^5 - x^4 + x^3 - x^3 - 1 \\ &= (x^5 - x^4 + x^3) - (x^3 + 1) \\ &= x^3(x^2-x+1) -(x+1)(x^2-x+1) \\ &= (x^2-x+1)(x^3-x-1). \end{aligned} $$

他の方法: $x^2-x+1 = 0$ (これの2つの解は虚数)のとき $x^3=-1$ なので, $x^5-x^4-1=-x^2+x-1=0$ となるので, $x^5 - x^4 - 1$ は $x^2-x+1$ で割り切れることがわかる.

以下では素朴な方法でも同じ結果が得られることを示す.

係数を $P,Q,R,S,T$ に代入する.

In [36]:

_, P, Q, R, S, T = all_coeffs(FF, x)

Out[36]:

$\left[ \begin{array}{r}\displaystyle 1\\\displaystyle -1\\\displaystyle 0\\\displaystyle 0\\\displaystyle 0\\\displaystyle -1\end{array} \right]$

余りの定数項が0になるという条件.

In [37]:

Eqrem0 = eqrem0(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[37]:

$\displaystyle a^{3} + a^{2} - 2 a b - b - \frac{1}{b}$

余りの1次の項が0になるという条件.

In [38]:

Eqrem1 = eqrem1(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[38]:

$\displaystyle a^{4} + a^{3} - 3 a^{2} b - 2 a b + b^{2}$

$be=-1$ となる整数の組 $(b,d)$ の各々について, 最下段の方程式が整数解を持つかどうかを確認する.

In [39]:

factor_for_all_divisors(Eqrem0, b, N(T))

Out[39]:

$\left[ \begin{array}{rr}\displaystyle 1&\displaystyle \left(a + 1\right) \left(a^{2} - 2\right)\\\displaystyle -1&\displaystyle \left(a + 1\right) \left(a^{2} + 2\right)\end{array}\right]$

$b=\pm 1$ の両方の場合に整数解 $a=-1$ を持つことがわかった.

これらが下から2段目の方程式も満たしているかを確認する.

In [40]:

BB, AA = 1, -1
Eqrem1(a=>AA, b=>BB)

Out[40]:

$\displaystyle 0$

In [41]:

BB, AA = -1, -1
Eqrem1(a=>AA, b=>BB)

Out[41]:

$\displaystyle 2$

$(a, b) = -1, 1$ の場合のみが解になっていることがわかった.

以下は検算である.

In [42]:

AA, BB = -1, 1
CC, DD, EE = C(a=>AA, b=>BB, p=>P), D(a=>AA, b=>BB, p=>P, q=>Q), E(a=>AA, b=>BB, p=>P, q=>Q, r=>R, t=>T)

Out[42]:

(0, -1, -1)

In [43]:

sol = (x^2 + AA*x + BB)*(x^3 + CC*x^2 + DD*x + EE)

Out[43]:

$\displaystyle \left(x^{2} - x + 1\right) \left(x^{3} - x - 1\right)$

In [44]:

sol - FF |> simplify

Out[44]:

$\displaystyle 0$

例3¶

$f = x^5 + 16x + 32$ の因数分解.

In [45]:

FF = x^5 + 16x + 32

Out[45]:

$\displaystyle x^{5} + 16 x + 32$

既存の函数を使えば易しい.

In [46]:

factor(FF)

Out[46]:

$\displaystyle \left(x^{2} + 2 x + 4\right) \left(x^{3} - 2 x^{2} + 8\right)$

$f$ に $x=2z$ を代入して得られる

$$ f|_{x=2z} = 32(z^5+z+1) $$

は $z^2+z+1=0$ (これの2つの解は虚数)のとき, $z^3=1$, $z^5=z^2$ となるので $0$ になる.

ゆえに $z^2+z+1$ に $z=x/2$ を代入したものの4倍

$$ x^2 + 2x + 4 $$

で $f$ は割り切れる.

以下では素朴な方法でも同じ結果が得られることを示そう.

係数を $P,Q,R,S,T$ に代入する.

In [47]:

_, P, Q, R, S, T = all_coeffs(FF, x)

Out[47]:

$\left[ \begin{array}{r}\displaystyle 1\\\displaystyle 0\\\displaystyle 0\\\displaystyle 0\\\displaystyle 16\\\displaystyle 32\end{array} \right]$

余りの定数項が0になるという条件.

In [48]:

Eqrem0 = eqrem0(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[48]:

$\displaystyle a^{3} - 2 a b + \frac{32}{b}$

余りの1次の項が0になるという条件.

In [49]:

Eqrem1 = eqrem1(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[49]:

$\displaystyle a^{4} - 3 a^{2} b + b^{2} + 16$

$b$ として $32$ の約数全体を動かして, eqrem0 を0にする整数 $a$ が存在する場合を探す.

In [50]:

factor_for_all_divisors(Eqrem0, b, N(T))

Out[50]:

$\left[ \begin{array}{rr}\displaystyle 1&\displaystyle a^{3} - 2 a + 32\\\displaystyle -1&\displaystyle a^{3} + 2 a - 32\\\displaystyle 2&\displaystyle a^{3} - 4 a + 16\\\displaystyle -2&\displaystyle \left(a - 2\right) \left(a^{2} + 2 a + 8\right)\\\displaystyle 4&\displaystyle \left(a - 2\right) \left(a^{2} + 2 a - 4\right)\\\displaystyle -4&\displaystyle a^{3} + 8 a - 8\\\displaystyle 8&\displaystyle a^{3} - 16 a + 4\\\displaystyle -8&\displaystyle a^{3} + 16 a - 4\\\displaystyle 16&\displaystyle a^{3} - 32 a + 2\\\displaystyle -16&\displaystyle a^{3} + 32 a - 2\\\displaystyle 32&\displaystyle a^{3} - 64 a + 1\\\displaystyle -32&\displaystyle a^{3} + 64 a - 1\end{array}\right]$

方程式 eqrem0 = 0 は $b=4,-2$ のときにのみ整数解 $a=2$ を持つことがわかった.

In [51]:

BB, AA = 4, 2
Eqrem1(a=>AA, b=>BB)

Out[51]:

$\displaystyle 0$

In [52]:

BB, AA = -2, 2
Eqrem1(a=>AA, b=>BB)

Out[52]:

$\displaystyle 60$

方程式 eqrem0 = eqrem1 = 0 の整数解 $a = 2$, $b=4$ が見付かった.

In [53]:

AA, BB = 2, 4
CC, DD, EE = C(a=>AA, b=>BB, p=>P), D(a=>AA, b=>BB, p=>P, q=>Q), E(a=>AA, b=>BB, p=>P, q=>Q, r=>R, t=>T)

Out[53]:

(-2, 0, 8)

In [54]:

sol = (x^2 + AA*x + BB)*(x^3 + CC*x^2 + DD*x + EE)

Out[54]:

$\displaystyle \left(x^{2} + 2 x + 4\right) \left(x^{3} - 2 x^{2} + 8\right)$

In [55]:

sol - FF |> simplify

Out[55]:

$\displaystyle 0$

例4¶

$f = x^5 + 3x^4 - 2x^3 - 2x^2 - 6x + 4$ の因数分解

In [56]:

FF = x^5 + 3x^4 - 2x^3 - 2x^2 - 6x + 4

Out[56]:

$\displaystyle x^{5} + 3 x^{4} - 2 x^{3} - 2 x^{2} - 6 x + 4$

In [57]:

factor(FF)

Out[57]:

$\displaystyle \left(x^{3} - 2\right) \left(x^{2} + 3 x - 2\right)$

$f$ が $x^k + a$ 型の因子を持つと決め打ちできるなら, そのように $f$ を整理すれば容易に因数分解できる.

$$ \begin{aligned} x^5 + 3x^4 - 2x^3 - 2x^2 - 6x + 4 &= (x^5 + 3x^4 - 2x^3) - (2x^2 + 6x - 4) \\ &= x^3(x^2 + 3x - 2) - 2(x^2 + 3x - 2) \\ &= (x^3-2)(x^2 + 3x - 2). \end{aligned} $$

In [58]:

factor(FF)

Out[58]:

$\displaystyle \left(x^{3} - 2\right) \left(x^{2} + 3 x - 2\right)$

In [59]:

_, P, Q, R, S, T = all_coeffs(FF, x)

Out[59]:

$\left[ \begin{array}{r}\displaystyle 1\\\displaystyle 3\\\displaystyle -2\\\displaystyle -2\\\displaystyle -6\\\displaystyle 4\end{array} \right]$

In [60]:

eqrem0

Out[60]:

$\displaystyle a^{3} - a^{2} p - 2 a b + a q + b p - r + \frac{t}{b}$

In [61]:

Eqrem0 = eqrem0(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[61]:

$\displaystyle a^{3} - 3 a^{2} - 2 a b - 2 a + 3 b + 2 + \frac{4}{b}$

In [62]:

eqrem1

Out[62]:

$\displaystyle a^{4} - a^{3} p - 3 a^{2} b + a^{2} q + 2 a b p - a r + b^{2} - b q + s$

In [63]:

Eqrem1 = eqrem1(p=>P, q=>Q, r=>R, s=>S, t=>T)

Out[63]:

$\displaystyle a^{4} - 3 a^{3} - 3 a^{2} b - 2 a^{2} + 6 a b + 2 a + b^{2} + 2 b - 6$

In [64]:

factor_for_all_divisors(Eqrem0, b, N(T))

Out[64]:

$\left[ \begin{array}{rr}\displaystyle 1&\displaystyle a^{3} - 3 a^{2} - 4 a + 9\\\displaystyle -1&\displaystyle a^{3} - 3 a^{2} - 5\\\displaystyle 2&\displaystyle a^{3} - 3 a^{2} - 6 a + 10\\\displaystyle -2&\displaystyle \left(a - 3\right) \left(a^{2} + 2\right)\\\displaystyle 4&\displaystyle a^{3} - 3 a^{2} - 10 a + 15\\\displaystyle -4&\displaystyle a^{3} - 3 a^{2} + 6 a - 11\end{array}\right]$

In [65]:

BB, AA = -2, 3
Eqrem1(a=>AA, b=>BB)

Out[65]:

$\displaystyle 0$

In [66]:

AA, BB = 3, -2
CC, DD, EE = C(a=>AA, b=>BB, p=>P), D(a=>AA, b=>BB, p=>P, q=>Q), E(a=>AA, b=>BB, p=>P, q=>Q, r=>R, t=>T)

Out[66]:

(0, 0, -2)

In [67]:

sol = (x^2 + AA*x + BB)*(x^3 + CC*x^2 + DD*x + EE)

Out[67]:

$\displaystyle \left(x^{3} - 2\right) \left(x^{2} + 3 x - 2\right)$

In [68]:

sol - FF |> simplify

Out[68]:

$\displaystyle 0$

In [ ]: