AdS Poincaré horizon as a degenerate Killing horizon

This notebook demonstrates some capabilities of SageMath in computations regarding the Poincaré horizon of the 4-dimensional anti-de Sitter spacetime. It also provides computations and figures for Example 17 of Chap. 3 of the lecture notes Geometry and physics of black holes.

The corresponding tools have been developed within the SageManifolds project.

In [1]:
version()
Out[1]:
'SageMath version 9.5.beta1, Release Date: 2021-09-13'

First we set up the notebook to display mathematical objects using LaTeX rendering and we ask for running tensor computations in parallel on 8 threads:

In [2]:
%display latex
Parallelism().set(nproc=8)

Spacetime manifold

We declare the anti-de Sitter spacetime as a 4-dimensional Lorentzian manifold:

In [3]:
M = Manifold(4, 'M', latex_name=r'\mathscr{M}', structure='Lorentzian')
print(M)
M
4-dimensional Lorentzian manifold M
Out[3]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathscr{M}\]

and endow it with the conformal coordinates $(\tau, \chi, \theta,\phi)$ (cf. the generic anti-de Sitter notebook):

In [4]:
X_conf.<ta,ch,th,ph> = M.chart(r'ta:\tau ch:(0,pi/2):\chi th:(0,pi):\theta ph:(0,2*pi):periodic:\phi')
print(X_conf)
X_conf
Chart (M, (ta, ch, th, ph))
Out[4]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathscr{M},({\tau}, {\chi}, {\theta}, {\phi})\right)\]
In [5]:
X_conf.coord_range()
Out[5]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}{\tau} :\ \left( -\infty, +\infty \right) ;\quad {\chi} :\ \left( 0 , \frac{1}{2} \, \pi \right) ;\quad {\theta} :\ \left( 0 , \pi \right) ;\quad {\phi} :\ \left[ 0 , 2 \, \pi \right] \mbox{(periodic)}\]

Spacetime metric

First of all, we declare the AdS length scale $\ell$ as a symbolic variable:

In [6]:
var('l', latex_name=r'\ell', domain='real')
assume(l>0)

Then we define the metric tensor $g$ by providing its nonzero components:

In [7]:
g = M.metric()
g[0,0] = -l^2/cos(ch)^2
g[1,1] = l^2/cos(ch)^2
g[2,2] = l^2/cos(ch)^2*sin(ch)^2
g[3,3] = l^2/cos(ch)^2*sin(ch)^2*sin(th)^2
g.display()
Out[7]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}g = -\frac{{\ell}^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} + \frac{{\ell}^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \frac{{\ell}^{2} \sin\left({\chi}\right)^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{{\ell}^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}\]

Let us check that $g$ is a solution of the vaccum Einstein equation with the cosmological constant $\Lambda = - 3 /\ell^2$:

In [8]:
Ric = g.ricci()
R = g.ricci_scalar()
Lambda = -3/l^2

Ric - 1/2*R*g + Lambda*g == 0
Out[8]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}\]

Poincaré patch

The Poincaré patch is the open subset $\mathscr{M}_{\rm P}$ of $\mathscr{M}$ defined by $$ \cos\tau - \sin\chi \sin\theta \cos\phi > 0 \quad\mbox{and}\quad -\pi < \tau < \pi.$$ Hence we declare it as

In [9]:
MP = M.open_subset('MP', latex_name=r'\mathscr{M}_{\rm P}', 
                   coord_def={X_conf: [cos(ta) - sin(ch)*sin(th)*cos(ph)>0, ta>-pi, ta<pi]})
print(MP)
MP
Open subset MP of the 4-dimensional Lorentzian manifold M
Out[9]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathscr{M}_{\rm P}\]

We introduce the Poincaré coordinates $(t,x,y,u)$ on $\mathscr{M}_{\rm P}$ as

In [10]:
X_Poinc.<t,x,y,u> = MP.chart('t x y u:(0,+oo)')
X_Poinc
Out[10]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathscr{M}_{\rm P},(t, x, y, u)\right)\]
In [11]:
X_Poinc.coord_range()
Out[11]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}t :\ \left( -\infty, +\infty \right) ;\quad x :\ \left( -\infty, +\infty \right) ;\quad y :\ \left( -\infty, +\infty \right) ;\quad u :\ \left( 0 , +\infty \right)\]

The Poincaré coordinates are defined by their link to the conformal coordinates, which we declare via the method transition_map on the restriction of the conformal coordinates to $\mathscr{M}_{\rm P}$, X_conf.restrict(MP):

In [12]:
conf_to_Poinc = X_conf.restrict(MP).transition_map(X_Poinc, 
                            [l*sin(ta)/(cos(ta) - sin(ch)*sin(th)*cos(ph)),
                             l*sin(ch)*sin(th)*sin(ph)/(cos(ta) - sin(ch)*sin(th)*cos(ph)),
                             l*sin(ch)*cos(th)/(cos(ta) - sin(ch)*sin(th)*cos(ph)),
                             l*(cos(ta) - sin(ch)*sin(th)*cos(ph))/cos(ch)])
conf_to_Poinc.display()
Out[12]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} t & = & -\frac{{\ell} \sin\left({\tau}\right)}{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right)} \\ x & = & -\frac{{\ell} \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right)} \\ y & = & -\frac{{\ell} \cos\left({\theta}\right) \sin\left({\chi}\right)}{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right)} \\ u & = & -\frac{{\left(\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right)\right)} {\ell}}{\cos\left({\chi}\right)} \end{array}\right.\]

In order to help SageMath with simplifications, we explicitly set some assumptions:

In [13]:
assume(sin(ch)>0, sin(th)>0)
assume(cos(ta) - sin(ch)*sin(th)*cos(ph)>0)

We provide the inverse of the coordinate change $(\tau,\chi,\theta,\phi) \mapsto (t,x,y,u)$ by means of the method set_inverse:

In [14]:
conf_to_Poinc.set_inverse(atan2(2*l*t, x^2+y^2-t^2+l^2*(1+l^2/u^2)),
            acos(2*l^3/u/sqrt((x^2+y^2-t^2+l^2*(1+l^2/u^2))^2 + 4*l^2*t^2)),
            acos(2*l*y/sqrt((x^2+y^2-t^2+l^2*(1+l^2/u^2))^2
                                                    + 4*l^2*(t^2-l^4/u^2))),
            atan2(2*l*x, x^2+y^2-t^2-l^2*(1-l^2/u^2)))          
Check of the inverse coordinate transformation:
  ta == -arctan2(2*l^2*sin(ta)/(cos(ph)*sin(ch)*sin(th) - cos(ta)), -2*l^2*cos(ta)/(cos(ph)*sin(ch)*sin(th) - cos(ta)))  **failed**
  ch == ch  *passed*
  th == th  *passed*
  ph == -arctan2(2*l^2*sin(ch)*sin(ph)*sin(th)/(cos(ph)*sin(ch)*sin(th) - cos(ta)), -2*l^2*cos(ph)*sin(ch)*sin(th)/(cos(ph)*sin(ch)*sin(th) - cos(ta)))  **failed**
  t == t  *passed*
  x == x  *passed*
  y == y  *passed*
  u == u  *passed*
NB: a failed report can reflect a mere lack of simplification.
In [15]:
conf_to_Poinc.inverse().display()
Out[15]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left\{\begin{array}{lcl} {\tau} & = & \arctan\left(2 \, {\ell} t, {\ell}^{2} {\left(\frac{{\ell}^{2}}{u^{2}} + 1\right)} - t^{2} + x^{2} + y^{2}\right) \\ {\chi} & = & \arccos\left(\frac{2 \, {\ell}^{3}}{\sqrt{4 \, {\ell}^{2} t^{2} + {\left({\ell}^{2} {\left(\frac{{\ell}^{2}}{u^{2}} + 1\right)} - t^{2} + x^{2} + y^{2}\right)}^{2}} u}\right) \\ {\theta} & = & \arccos\left(\frac{2 \, {\ell} y}{\sqrt{4 \, {\left(t^{2} - \frac{{\ell}^{4}}{u^{2}}\right)} {\ell}^{2} + {\left({\ell}^{2} {\left(\frac{{\ell}^{2}}{u^{2}} + 1\right)} - t^{2} + x^{2} + y^{2}\right)}^{2}}}\right) \\ {\phi} & = & \arctan\left(2 \, {\ell} x, {\ell}^{2} {\left(\frac{{\ell}^{2}}{u^{2}} - 1\right)} - t^{2} + x^{2} + y^{2}\right) \end{array}\right.\]

We note that the Jacobian of the coordinate change is quite involved:

In [16]:
conf_to_Poinc.jacobian()
Out[16]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrrr} -\frac{{\ell} \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - {\ell}}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & \frac{{\ell} \cos\left({\chi}\right) \cos\left({\phi}\right) \sin\left({\tau}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & \frac{{\ell} \cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\tau}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & -\frac{{\ell} \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\tau}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} \\ \frac{{\ell} \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\tau}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & \frac{{\ell} \cos\left({\chi}\right) \cos\left({\tau}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & \frac{{\ell} \cos\left({\tau}\right) \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\phi}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & \frac{{\ell} \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - {\ell} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} \\ \frac{{\ell} \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\tau}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & \frac{{\ell} \cos\left({\chi}\right) \cos\left({\tau}\right) \cos\left({\theta}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & \frac{{\ell} \cos\left({\phi}\right) \sin\left({\chi}\right)^{2} - {\ell} \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} & -\frac{{\ell} \cos\left({\theta}\right) \sin\left({\chi}\right)^{2} \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2}} \\ -\frac{{\ell} \sin\left({\tau}\right)}{\cos\left({\chi}\right)} & \frac{{\ell} \cos\left({\tau}\right) \sin\left({\chi}\right) - {\ell} \cos\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)^{2}} & -\frac{{\ell} \cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\chi}\right)}{\cos\left({\chi}\right)} & \frac{{\ell} \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)} \end{array}\right)\]

Plot of the Poincaré coordinate grid in terms of the conformal coordinates $(\tau,\chi)$

For plotting purposes, we introduce the 2-dimensional plane $\mathbb{R}^2$, spanned by Cartesian coordinates $(\tau, x_\chi)$:

In [17]:
R2 = Manifold(2, 'R^2', latex_name=r'\mathbb{R}^2')
X2.<ta, x_ch> = R2.chart(r'ta:\tau x_ch:x_\chi')
X2
Out[17]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathbb{R}^2,({\tau}, {x_\chi})\right)\]

and define the following map from AdS spacetime to $\mathbb{R}^2$:

In [18]:
Phi = M.diff_map(R2, {(X_conf, X2): [ta, ch*cos(ph)]})
Phi.display()
Out[18]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathscr{M} & \longrightarrow & \mathbb{R}^2 \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, {x_\chi}\right) = \left({\tau}, {\chi} \cos\left({\phi}\right)\right) \end{array}\]

Let us the grid of coordinates $(t,u)$ for $(x,y)=(0,0)$ in terms of the coordinates $(\tau,\chi)$. This is achieved by using the method plot on the chart X_Poinc:

In [19]:
graph1 = X_Poinc.plot(X2, ambient_coords=(x_ch, ta), mapping=Phi.restrict(MP),
                      fixed_coords={x: 0, y: 0}, 
                      ranges={t: (-15, 15), u: (0.01, 12)}, parameters={l: 1},
                      color={t: 'red', u: 'grey'}, number_values={t: 33, u: 25}, 
                      plot_points=200)

We superpose the plot of the Poincaré horizon and a few labels:

In [20]:
graph = polygon([(-pi/2, -pi), (pi/2, 0), (-pi/2, pi)], color='cornsilk')
graph += graph1
graph_hor = plot(pi/2 - ch, (ch, -pi/2, pi/2), color='green',
                 thickness=3) \
           + plot(ch - pi/2, (ch, -pi/2, pi/2), color='green',
                  thickness=3) \
           + text(r'$\mathscr{H}$', (-0.9, 2.85), fontsize=18, color='green')
graph += graph_hor
region_labels = text(r'$\mathscr{M}$', (1, 2.5), fontsize=18, color='black') \
                + text(r'$\mathscr{M}_{\rm P}$', (-0.4, 0.5), fontsize=18, 
                       color='black')
graph += region_labels

show(graph, frame=True, gridlines=True, figsize=8)
graph.save('neh_AdS_Poincare_patch.pdf', frame=True, 
           gridlines=True, figsize=8)

Metric tensor in terms of Poincaré coordinates

The computation of the metric components with respect to Poincaré coordinates is triggered by the method display when it receives the Poincaré chart X_Poinc as an argument:

In [21]:
g.display(X_Poinc)
Out[21]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}g = -\frac{u^{2}}{{\ell}^{2}} \mathrm{d} t\otimes \mathrm{d} t + \frac{u^{2}}{{\ell}^{2}} \mathrm{d} x\otimes \mathrm{d} x + \frac{u^{2}}{{\ell}^{2}} \mathrm{d} y\otimes \mathrm{d} y + \frac{{\ell}^{2}}{u^{2}} \mathrm{d} u\otimes \mathrm{d} u\]

Killing vector $\xi$

Since the above components of $g$ do not depend of $t$, the coordinate vector $\displaystyle\frac{\partial}{\partial t}$ is clearly a Killing vector of $(\mathscr{M}_{\rm P}, g)$. Its expression in terms the conformal coordinates is

In [22]:
vt = X_Poinc.frame()[0]
vt.display()
Out[22]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\frac{\partial}{\partial t } = \left( -\frac{\cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - 1}{{\ell}} \right) \frac{\partial}{\partial {\tau} } -\frac{\cos\left({\chi}\right) \cos\left({\phi}\right) \sin\left({\tau}\right) \sin\left({\theta}\right)}{{\ell}} \frac{\partial}{\partial {\chi} } -\frac{\cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\tau}\right)}{{\ell} \sin\left({\chi}\right)} \frac{\partial}{\partial {\theta} } + \frac{\sin\left({\phi}\right) \sin\left({\tau}\right)}{{\ell} \sin\left({\chi}\right) \sin\left({\theta}\right)} \frac{\partial}{\partial {\phi} }\]

Let us check that $\xi$ is indeed a Killing vector of $(\mathcal{M}_{\rm P}, g)$:

In [23]:
g.restrict(MP).lie_derivative(vt).display()
Out[23]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}0\]

We note that the components of $\partial/\partial t$ with respect to conformal coordinates are smooth functions of $(\tau,\chi,\theta,\phi)$ that can be extended beyond $\mathscr{M}_{\rm P}$. We may therefore extend $\partial/\partial t$ to a vector field $\xi$ defined on the entire AdS spacetime $\mathscr{M}$:

In [24]:
xi = M.vector_field([vt[i].expr() for i in M.irange()], 
                    name='xi', latex_name=r'\xi')
xi.display()
Out[24]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\xi = \left( -\frac{\cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - 1}{{\ell}} \right) \frac{\partial}{\partial {\tau} } -\frac{\cos\left({\chi}\right) \cos\left({\phi}\right) \sin\left({\tau}\right) \sin\left({\theta}\right)}{{\ell}} \frac{\partial}{\partial {\chi} } -\frac{\cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\tau}\right)}{{\ell} \sin\left({\chi}\right)} \frac{\partial}{\partial {\theta} } + \frac{\sin\left({\phi}\right) \sin\left({\tau}\right)}{{\ell} \sin\left({\chi}\right) \sin\left({\theta}\right)} \frac{\partial}{\partial {\phi} }\]

Let us check that the restriction of $\xi$ to $\mathscr{M}_{\rm P}$ coincides with $\partial/\partial t$:

In [25]:
xi.restrict(MP).display(X_Poinc)
Out[25]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\xi = \frac{\partial}{\partial t }\]

$\xi$ is a global Killing vector:

In [26]:
g.lie_derivative(xi).display()
Out[26]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}0\]

Another view of the same property by forming the Killing equation $\nabla_a \xi_b + \nabla_b \xi_a = 0$:

In [27]:
nabla = g.connection()

nabla(xi.down(g)).symmetrize().display()
Out[27]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}0\]

Plot of $\xi$

In [28]:
graph = polygon([(-pi/2, -pi), (pi/2, 0), (-pi/2, pi)], color='cornsilk')

graph += xi.plot(X2, ambient_coords=(x_ch, ta), mapping=Phi,
                 fixed_coords={th: pi/2}, parameters={l: 1},
                 ranges={ta: (-pi, pi)}, number_values={ta: 11, ch: 7, ph: 3},
                 color='red', scale=0.3, arrowsize=2)

graph += graph_hor
show(graph, frame=True, gridlines=True, figsize=8, aspect_ratio=1)
graph.save("neh_AdS_Killing_vec.pdf", frame=True, gridlines=True, 
           figsize=8, aspect_ratio=1)

$u$ as a scalar field on the whole AdS spacetime

The expression of the Poincaré coordinate $u$ in terms of the conformal coordinates $(\tau,\chi,\theta,\phi)$ is read as the last component (index 3) of the coordinate transformation conf_to_Poinc, which implements $(\tau,\chi,\theta,\phi)\mapsto (t,x,y,u)$:

In [29]:
conf_to_Poinc(ta, ch, th, ph)
Out[29]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left(-\frac{{\ell} \sin\left({\tau}\right)}{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right)}, -\frac{{\ell} \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right)}, -\frac{{\ell} \cos\left({\theta}\right) \sin\left({\chi}\right)}{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right)}, -\frac{{\ell} \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - {\ell} \cos\left({\tau}\right)}{\cos\left({\chi}\right)}\right)\]
In [30]:
conf_to_Poinc(ta, ch, th, ph)[3]
Out[30]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}-\frac{{\ell} \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - {\ell} \cos\left({\tau}\right)}{\cos\left({\chi}\right)}\]

This expression being regular in all $\mathscr{M}$, we may extend $u$ to a scalar field defined on $\mathscr{M}$ by

In [31]:
U = M.scalar_field(conf_to_Poinc(ta, ch, th, ph)[3], name='u')
U.display()
Out[31]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} u:& \mathscr{M} & \longrightarrow & \mathbb{R} \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & -\frac{{\ell} \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - {\ell} \cos\left({\tau}\right)}{\cos\left({\chi}\right)} \\ \mbox{on}\ \mathscr{M}_{\rm P} : & \left(t, x, y, u\right) & \longmapsto & u \end{array}\]

The Poincaré horizon as the submanifold $u=0$

The Poincaré horizon is the hypersurface $\mathscr{H}$ bounding the Poincaré patch $\mathscr{M}_{\rm P}$ in $\mathscr{M}$. It follows that $\mathscr{H}$ is the level set $u=0$ within the region $-\pi<\tau<\pi$. $\mathscr{H}$ has actually two connected components: one for $-\pi < \tau < 0$ and the other one for $0 < \tau <\pi$. In what follows, we focus on the connected component that has $0 < \tau <\pi$; we define it as a submanifold of $\mathscr{M}$, by means of the keyword ambient in the function Manifold:

In [32]:
H = Manifold(3, 'H', ambient=M, latex_name=r'\mathscr{H}')
print(H)
3-dimensional differentiable submanifold H immersed in the 4-dimensional Lorentzian manifold M

We consider that $\mathscr{H}$ is spanned by the coordinates $(\chi,\theta,\phi)$, so that we declare the following chart:

In [33]:
XH.<ch,th,ph> = H.chart(r'ch:(0,pi/2):\chi th:(0,pi):\theta ph:(0,2*pi):periodic:\phi')
XH
Out[33]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left(\mathscr{H},({\chi}, {\theta}, {\phi})\right)\]

The embedding $F$ of $\mathscr{H}$ into $\mathscr{M}$ is easily defined in the pair of charts (XH, X_conf) by noticing that, for $0 < \tau <\pi$, $u=0 \iff \tau = \arccos(\sin\chi\sin\theta\cos\phi)$:

In [34]:
F = H.diff_map(M, {(XH, X_conf): (acos(sin(ch)*sin(th)*cos(ph)), ch, th, ph)},
               name='F')
F.display()
Out[34]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} F:& \mathscr{H} & \longrightarrow & \mathscr{M} \\ & \left({\chi}, {\theta}, {\phi}\right) & \longmapsto & \left({\tau}, {\chi}, {\theta}, {\phi}\right) = \left(\arccos\left(\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)\right), {\chi}, {\theta}, {\phi}\right) \end{array}\]

We declare that $F$ is the embedding of $\mathscr{H}$ into $\mathscr{M}$, thereby ending the definition of $\mathscr{H}$:

In [35]:
H.set_embedding(F)
print(H)
3-dimensional differentiable submanifold H embedded in the 4-dimensional Lorentzian manifold M

We may check that the scalar field $u$ is zero on $\mathscr{H}$ by considering the pullback of $u$ by $F$:

In [36]:
FU = F.pullback(U)
print(FU)
Scalar field F^*(u) on the 3-dimensional differentiable submanifold H embedded in the 4-dimensional Lorentzian manifold M
In [37]:
FU.display()
Out[37]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} {F}^*u:& \mathscr{H} & \longrightarrow & \mathbb{R} \\ & \left({\chi}, {\theta}, {\phi}\right) & \longmapsto & 0 \end{array}\]

Null character of the hypersurface $\mathscr{H}$

The metric induced by $g$ on $\mathscr{H}$ is obtained as the pullback of $g$ by the embedding $F$:

In [38]:
Fg = F.pullback(g)
print(Fg)
Field of symmetric bilinear forms F^*(g) on the 3-dimensional differentiable submanifold H embedded in the 4-dimensional Lorentzian manifold M
In [39]:
Fg.display()
Out[39]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}{F}^*g = \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\theta}\right)^{2} - {\ell}^{2}}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\theta} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\phi} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\chi} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{4} \sin\left({\theta}\right)^{2} + {\ell}^{2} \cos\left({\phi}\right)^{2} \cos\left({\theta}\right)^{2} \sin\left({\chi}\right)^{2} - {\ell}^{2} \sin\left({\chi}\right)^{2}}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\chi}\right)^{2} \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\phi} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\chi} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\chi}\right)^{2} \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\theta} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{4} \sin\left({\theta}\right)^{4} - {\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}\]

We declare a metric $h$ on $\mathscr{H}$ and initialize it with the pullback $F^* g$:

In [40]:
h = H.metric('h')
h.set(Fg)
h.display()
Out[40]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}h = \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\theta}\right)^{2} - {\ell}^{2}}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\theta} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\chi}\otimes \mathrm{d} {\phi} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\chi} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{4} \sin\left({\theta}\right)^{2} + {\ell}^{2} \cos\left({\phi}\right)^{2} \cos\left({\theta}\right)^{2} \sin\left({\chi}\right)^{2} - {\ell}^{2} \sin\left({\chi}\right)^{2}}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\chi}\right)^{2} \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\phi} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right) \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\chi} + \left( -\frac{{\ell}^{2} \cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\chi}\right)^{2} \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\theta} + \left( \frac{{\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{4} \sin\left({\theta}\right)^{4} - {\ell}^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - \cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}\]

This is a degenerate metric:

In [41]:
h.determinant().display()
Out[41]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} & \mathscr{H} & \longrightarrow & \mathbb{R} \\ & \left({\chi}, {\theta}, {\phi}\right) & \longmapsto & 0 \end{array}\]

Hence the Poincaré horizon $\mathscr{H}$ is a null hypersurface.

The normal to the Poincaré horizon

Since $\mathscr{H}$ is the isosurface $u=0$, its normal $k$ is defined as the gradient of $u$:

In [42]:
dU = diff(U)
dU.display()
Out[42]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}u = -\frac{{\ell} \sin\left({\tau}\right)}{\cos\left({\chi}\right)} \mathrm{d} {\tau} + \left( \frac{{\ell} \cos\left({\tau}\right) \sin\left({\chi}\right) - {\ell} \cos\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)^{2}} \right) \mathrm{d} {\chi} -\frac{{\ell} \cos\left({\phi}\right) \cos\left({\theta}\right) \sin\left({\chi}\right)}{\cos\left({\chi}\right)} \mathrm{d} {\theta} + \frac{{\ell} \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)}{\cos\left({\chi}\right)} \mathrm{d} {\phi}\]

dU is a 1-form; we turn it into a vector field by raising its index with the metric $g$, via the method up:

In [43]:
k = dU.up(g)
k.set_name('k')
k.display()
Out[43]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}k = \frac{\cos\left({\chi}\right) \sin\left({\tau}\right)}{{\ell}} \frac{\partial}{\partial {\tau} } + \left( \frac{\cos\left({\tau}\right) \sin\left({\chi}\right) - \cos\left({\phi}\right) \sin\left({\theta}\right)}{{\ell}} \right) \frac{\partial}{\partial {\chi} } -\frac{\cos\left({\chi}\right) \cos\left({\phi}\right) \cos\left({\theta}\right)}{{\ell} \sin\left({\chi}\right)} \frac{\partial}{\partial {\theta} } + \frac{\cos\left({\chi}\right) \sin\left({\phi}\right)}{{\ell} \sin\left({\chi}\right) \sin\left({\theta}\right)} \frac{\partial}{\partial {\phi} }\]

Plot of $k$:

In [44]:
graph = k.plot(X2, ambient_coords=(x_ch, ta), mapping=Phi,
               fixed_coords={th: pi/2}, parameters={l: 1},
               ranges={ta: (-pi, pi)}, number_values={ta: 11, ch: 7, ph: 3},
               color='orange', scale=0.3, arrowsize=2)
graph += graph_hor
graph += line([(-pi/2, -pi), (-pi/2, pi)], color='black')
graph += line([(pi/2, -pi), (pi/2, pi)], color='black')
show(graph, frame=True, gridlines=True, figsize=8, aspect_ratio=1)

We note that, graphically, $k$ appears tangent to $\mathscr{H}$, in agreement with $\mathscr{H}$ being a null hypersurface (the only kind of hypersurface for which the normal is also tangent to the hypersurface).

The spacetime metric $g$ restricted to $\mathscr{H}$ is evaluated by means of the method along:

In [45]:
g_H = H.lorentzian_metric('g_H', latex_name=r'\left.g\right|_{\mathscr{H}}', 
                          dest_map=F)
g_H.set(g.along(F))
print(g_H)
Lorentzian metric g_H along the 3-dimensional differentiable submanifold H embedded in the 4-dimensional Lorentzian manifold M with values on the 4-dimensional Lorentzian manifold M
In [46]:
g_H.display()
Out[46]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left.g\right|_{\mathscr{H}} = -\frac{{\ell}^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} + \frac{{\ell}^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\chi}\otimes \mathrm{d} {\chi} + \frac{{\ell}^{2} \sin\left({\chi}\right)^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \frac{{\ell}^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}\]

The vector field $k$ restricted to $\mathscr{H}$:

In [47]:
k_H = k.along(F)
k_H.set_name('k_H', latex_name=r'\left.k\right|_{\mathscr{H}}')
print(k_H)
Vector field k_H along the 3-dimensional differentiable submanifold H embedded in the 4-dimensional Lorentzian manifold M with values on the 4-dimensional Lorentzian manifold M
In [48]:
k_H.display()
Out[48]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left.k\right|_{\mathscr{H}} = \left( \frac{\sqrt{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \sqrt{-\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \cos\left({\chi}\right)}{{\ell}} \right) \frac{\partial}{\partial {\tau} } -\frac{\cos\left({\chi}\right)^{2} \cos\left({\phi}\right) \sin\left({\theta}\right)}{{\ell}} \frac{\partial}{\partial {\chi} } -\frac{\cos\left({\chi}\right) \cos\left({\phi}\right) \cos\left({\theta}\right)}{{\ell} \sin\left({\chi}\right)} \frac{\partial}{\partial {\theta} } + \frac{\cos\left({\chi}\right) \sin\left({\phi}\right)}{{\ell} \sin\left({\chi}\right) \sin\left({\theta}\right)} \frac{\partial}{\partial {\phi} }\]

Check that $\left.k\right|_{\mathscr{H}}$ is a null vector field:

In [49]:
g_H(k_H, k_H).expr()
Out[49]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}0\]

Since $\left.k\right|_{\mathscr{H}}$ is normal to $\mathscr{H}$, we recover the fact that $\mathscr{H}$ is a null hypersurface.

Killing horizon character

The Killing vector field $\xi$ restricted to $\mathscr{H}$:

In [50]:
xi_H = xi.along(F)
xi_H.set_name('xi_H', latex_name=r'\left.\xi\right|_{\mathscr{H}}')
print(xi_H)
Vector field xi_H along the 3-dimensional differentiable submanifold H embedded in the 4-dimensional Lorentzian manifold M with values on the 4-dimensional Lorentzian manifold M
In [51]:
xi_H.display()
Out[51]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left.\xi\right|_{\mathscr{H}} = \left( -\frac{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 1}{{\ell}} \right) \frac{\partial}{\partial {\tau} } + \left( -\frac{\sqrt{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \sqrt{-\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \cos\left({\chi}\right) \cos\left({\phi}\right) \sin\left({\theta}\right)}{{\ell}} \right) \frac{\partial}{\partial {\chi} } + \left( -\frac{\sqrt{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \sqrt{-\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \cos\left({\phi}\right) \cos\left({\theta}\right)}{{\ell} \sin\left({\chi}\right)} \right) \frac{\partial}{\partial {\theta} } + \left( \frac{\sqrt{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \sqrt{-\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) + 1} \sin\left({\phi}\right)}{{\ell} \sin\left({\chi}\right) \sin\left({\theta}\right)} \right) \frac{\partial}{\partial {\phi} }\]

Value of $\tau$ on $\mathscr{H}$:

In [52]:
ta_H = F.expr()[0]
ta_H
Out[52]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\arccos\left(\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\theta}\right)\right)\]

We check that $ \xi \stackrel{\mathscr{H}}{=} \frac{\sin\tau}{\cos\chi} \, k $:

In [53]:
xi_H == sin(ta_H)/cos(ch)*k_H
Out[53]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}\]

Hence, on $\mathscr{H}$, the Killing vector $\xi$ is normal to $\mathscr{H}$. $\mathscr{H}$ being a null hypersurface, this implies that $\mathscr{H}$ is a Killing horizon.

As a consequence, $\xi$ must be a null vector on $\mathscr{H}$. We can check this property by computing the scalar square of $\xi$ in all $\mathscr{M}$:

In [54]:
xi2 = g(xi, xi)
xi2.display()
Out[54]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\begin{array}{llcl} g\left(\xi,\xi\right):& \mathscr{M} & \longrightarrow & \mathbb{R} \\ & \left({\tau}, {\chi}, {\theta}, {\phi}\right) & \longmapsto & -\frac{\cos\left({\phi}\right)^{2} \sin\left({\chi}\right)^{2} \sin\left({\theta}\right)^{2} - 2 \, \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \sin\left({\tau}\right)^{2} + 1}{\cos\left({\chi}\right)^{2}} \\ \mbox{on}\ \mathscr{M}_{\rm P} : & \left(t, x, y, u\right) & \longmapsto & -\frac{u^{2}}{{\ell}^{2}} \end{array}\]

and notice that it is equal to $-u^2/\ell^2$:

In [55]:
xi2 == - U^2/l^2
Out[55]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{True}\]

so that $\xi$ is null on $\mathscr{H}$ as a direct consequence of the vanishing of $u$ on $\mathscr{H}$. Incidentally, the above formula implies that the Killing vector $\xi$ is timelike everywhere on the AdS spacetime, except on the Poincaré horizon, where it is null.

Degenerate character of the Killing horizon $\mathscr{H}$

The non-affinity coefficient $\kappa$ of $\xi$ on $\mathscr{H}$ is defined by $\nabla_\xi \xi \stackrel{\mathscr{H}}{=} \kappa \xi$. To compute $\kappa$, we first compute the "acceleration" vector $\nabla_\xi \xi$:

In [56]:
acc = nabla(xi).contract(xi)
acc.display()
Out[56]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\left( -\frac{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\tau}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right) \sin\left({\tau}\right)}{{\ell}^{2}} \right) \frac{\partial}{\partial {\tau} } + \left( -\frac{\cos\left({\phi}\right)^{2} \cos\left({\theta}\right)^{2} \sin\left({\chi}\right) \sin\left({\tau}\right)^{2} - \cos\left({\phi}\right)^{2} \cos\left({\tau}\right)^{2} \sin\left({\chi}\right) \sin\left({\theta}\right)^{2} + \sin\left({\chi}\right) \sin\left({\phi}\right)^{2} \sin\left({\tau}\right)^{2} - {\left(\cos\left({\chi}\right)^{2} - 2\right)} \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\theta}\right) - \sin\left({\chi}\right)}{{\ell}^{2} \cos\left({\chi}\right)} \right) \frac{\partial}{\partial {\chi} } + \left( \frac{\cos\left({\phi}\right)^{2} \cos\left({\theta}\right) \sin\left({\chi}\right) \sin\left({\theta}\right) - \cos\left({\phi}\right) \cos\left({\tau}\right) \cos\left({\theta}\right)}{{\ell}^{2} \sin\left({\chi}\right)} \right) \frac{\partial}{\partial {\theta} } + \left( -\frac{\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right) \sin\left({\phi}\right)}{{\ell}^{2} \sin\left({\chi}\right) \sin\left({\theta}\right)} \right) \frac{\partial}{\partial {\phi} }\]

and subsquently evaluate it on $\mathscr{H}$:

In [57]:
acc.along(F).display()
Out[57]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}0\]

Hence we get $\kappa = 0$, so that the Poincaré horizon $\mathscr{H}$ is a degenerate Killing horizon.

Note that $\kappa = 0$ can also be obtained via the formula $$\mathrm{d}(\xi\cdot\xi) \stackrel{\mathscr{H}}{=} -2 \kappa \underline{\xi} . $$ which holds for any Killing horizon. The left hand side is computed as

In [58]:
dxi2 = diff(xi2)
dxi2.display()
Out[58]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}g\left(\xi,\xi\right) = -\frac{2 \, {\left(\cos\left({\phi}\right) \sin\left({\chi}\right) \sin\left({\tau}\right) \sin\left({\theta}\right) - \cos\left({\tau}\right) \sin\left({\tau}\right)\right)}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\tau} -\frac{2 \, {\left(\cos\left({\phi}\right)^{2} \sin\left({\chi}\right) \sin\left({\theta}\right)^{2} + {\left(\cos\left({\chi}\right)^{2} - 2\right)} \cos\left({\phi}\right) \cos\left({\tau}\right) \sin\left({\theta}\right) + \cos\left({\tau}\right)^{2} \sin\left({\chi}\right)\right)}}{\cos\left({\chi}\right)^{3}} \mathrm{d} {\chi} -\frac{2 \, {\left(\cos\left({\phi}\right)^{2} \cos\left({\theta}\right) \sin\left({\chi}\right)^{2} \sin\left({\theta}\right) - \cos\left({\phi}\right) \cos\left({\tau}\right) \cos\left({\theta}\right) \sin\left({\chi}\right)\right)}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\theta} + \frac{2 \, {\left(\cos\left({\phi}\right) \sin\left({\chi}\right)^{2} \sin\left({\phi}\right) \sin\left({\theta}\right)^{2} - \cos\left({\tau}\right) \sin\left({\chi}\right) \sin\left({\phi}\right) \sin\left({\theta}\right)\right)}}{\cos\left({\chi}\right)^{2}} \mathrm{d} {\phi}\]

The restriction of this 1-form to $\mathscr{H}$ is computed by means of the method along:

In [59]:
dxi2_H = dxi2.along(F)
print(dxi2_H)
1-form dg(xi,xi) along the 3-dimensional differentiable submanifold H embedded in the 4-dimensional Lorentzian manifold M with values on the 4-dimensional Lorentzian manifold M
In [60]:
dxi2_H.display()
Out[60]:
\[\newcommand{\Bold}[1]{\mathbf{#1}}\mathrm{d}g\left(\xi,\xi\right) = 0\]

Hence $\mathrm{d}(\xi\cdot\xi) \stackrel{\mathscr{H}}{=} 0$ and we recover $\kappa=0$.