# Near-horizon geometry of the extremal Kerr black hole¶

This notebook derives the near-horizon geometry of the extremal (i.e. maximally spinning) Kerr black hole. It is based on SageMath tools developed through the SageManifolds project.

This notebook requires a version of SageMath at least equal to 9.4:

In :
version()

Out:
'SageMath version 9.5.beta3, Release Date: 2021-10-11'

First we set up the notebook to display mathematical objects using LaTeX rendering:

In :
%display latex


To speed up computations, we ask for running them in parallel on 8 threads:

In :
Parallelism().set(nproc=8)


## Spacetime manifold¶

We declare the Kerr spacetime (or more precisely the part of it covered by Boyer-Lindquist coordinates) as a 4-dimensional Lorentzian manifold $\mathcal{M}$:

In :
M = Manifold(4, 'M', latex_name=r'\mathcal{M}', structure='Lorentzian')
print(M)

4-dimensional Lorentzian manifold M


We then introduce the standard Boyer-Lindquist coordinates $(t,r,\theta,\phi)$ as a chart BL (for Boyer-Lindquist) on $\mathcal{M}$, via the method chart(). The argument of the latter is a string (delimited by r"..." because of the backslash symbols) expressing the coordinates names, their ranges (the default is $(-\infty,+\infty)$) and their LaTeX symbols:

In :
BL.<t,r,th,ph> = M.chart(r"t r th:(0,pi):\theta ph:(0,2*pi):periodic:\phi")
print(BL); BL

Chart (M, (t, r, th, ph))

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\mathcal{M},(t, r, {\theta}, {\phi})\right)$
In :
BL, BL

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(t, r\right)$

## Metric tensor of the extremal Kerr spacetime¶

The mass parameter $m$ of the Kerr spacetime is declared as a symbolic variable:

In :
m = var('m', domain='real')


For the extremal Kerr black hole, the spin parameter $a$ reaches its upper bound, namely $m$:

In :
a = m


We get the (yet undefined) spacetime metric:

In :
g = M.metric()


The metric is set by its components in the coordinate frame associated with Boyer-Lindquist coordinates, which is the current manifold's default frame:

In :
rho2 = r^2 + (a*cos(th))^2
Delta = r^2 -2*m*r + a^2
g[0,0] = -(1-2*m*r/rho2)
g[0,3] = -2*a*m*r*sin(th)^2/rho2
g[1,1], g[2,2] = rho2/Delta, rho2
g[3,3] = (r^2+a^2+2*m*r*(a*sin(th))^2/rho2)*sin(th)^2
g.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}g = \left( \frac{2 \, m r}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{m^{2} \cos\left({\theta}\right)^{2} + r^{2}}{m^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( m^{2} \cos\left({\theta}\right)^{2} + r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + {\left(\frac{2 \, m^{3} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} + m^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

A matrix view of the components with respect to the manifold's default vector frame:

In :
g[:]

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\begin{array}{rrrr} \frac{2 \, m r}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 & 0 & 0 & -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ 0 & \frac{m^{2} \cos\left({\theta}\right)^{2} + r^{2}}{m^{2} - 2 \, m r + r^{2}} & 0 & 0 \\ 0 & 0 & m^{2} \cos\left({\theta}\right)^{2} + r^{2} & 0 \\ -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} & 0 & 0 & {\left(\frac{2 \, m^{3} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} + m^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \end{array}\right)$

The list of the non-vanishing components:

In :
g.display_comp()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\begin{array}{lcl} g_{ \, t \, t }^{ \phantom{\, t}\phantom{\, t} } & = & \frac{2 \, m r}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 \\ g_{ \, t \, {\phi} }^{ \phantom{\, t}\phantom{\, {\phi}} } & = & -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, r \, r }^{ \phantom{\, r}\phantom{\, r} } & = & \frac{m^{2} \cos\left({\theta}\right)^{2} + r^{2}}{m^{2} - 2 \, m r + r^{2}} \\ g_{ \, {\theta} \, {\theta} }^{ \phantom{\, {\theta}}\phantom{\, {\theta}} } & = & m^{2} \cos\left({\theta}\right)^{2} + r^{2} \\ g_{ \, {\phi} \, t }^{ \phantom{\, {\phi}}\phantom{\, t} } & = & -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} \\ g_{ \, {\phi} \, {\phi} }^{ \phantom{\, {\phi}}\phantom{\, {\phi}} } & = & {\left(\frac{2 \, m^{3} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} + m^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \end{array}$

Let us check that we are dealing with a solution of the vacuum Einstein equation:

In :
g.ricci().display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{Ric}\left(g\right) = 0$

## Near-horizon coordinates¶

Let us introduce the chart NH of the near-horizon coordinates $(T, R, \theta, \Phi)$:

In :
NH.<T,R,th,Ph> = M.chart(r"T R th:(0,pi):\theta Ph:(0,2*pi):periodic:\Phi")
print(NH)
NH

Chart (M, (T, R, th, Ph))

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\mathcal{M},(T, R, {\theta}, {\Phi})\right)$
In :
M.atlas()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left[\left(\mathcal{M},(t, r, {\theta}, {\phi})\right), \left(\mathcal{M},(T, R, {\theta}, {\Phi})\right)\right]$

Following J. Bardeen and G. T. Horowitz, Phys. Rev. D 60, 104030 (1999) (arXiv:hep-th/9905099), the near-horizon coordinates $(T, R, \theta, \Phi)$ are related to the Boyer-Lindquist coordinates by $$T = \epsilon \frac{t}{2m}, \quad R = \frac{r-m}{\epsilon m},\quad \theta = \theta, \quad\Phi = \phi - \frac{t}{2m},$$ where $\epsilon$ is a constant parameter. The horizon of the extremal Kerr black hole is located at $r=m$, which corresponds to $R=0$.

NB: the coordinates $T$ and $R$ introduced by Bardeen and Horowitz (BH), which are denoted $t$ and $r$ by them, are actually $T_{\rm BH} = 2m T$ and $R_{\rm BH} = m R$.

We implement the above relations as a transition map from the chart BL to the chart NH:

In :
eps = var('eps', latex_name=r'\epsilon')
BL_to_NH = BL.transition_map(NH, [eps*t/(2*m), (r-m)/(eps*m), th, ph - t/(2*m)])
BL_to_NH.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left\{\begin{array}{lcl} T & = & \frac{{\epsilon} t}{2 \, m} \\ R & = & -\frac{m - r}{{\epsilon} m} \\ {\theta} & = & {\theta} \\ {\Phi} & = & {\phi} - \frac{t}{2 \, m} \end{array}\right.$

The inverse relation is

In :
BL_to_NH.inverse().display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left\{\begin{array}{lcl} t & = & \frac{2 \, T m}{{\epsilon}} \\ r & = & {\left(R {\epsilon} + 1\right)} m \\ {\theta} & = & {\theta} \\ {\phi} & = & \frac{{\Phi} {\epsilon} + T}{{\epsilon}} \end{array}\right.$

Note that we have

In :
BL_to_NH.jacobian()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\begin{array}{rrrr} \frac{{\epsilon}}{2 \, m} & 0 & 0 & 0 \\ 0 & \frac{1}{{\epsilon} m} & 0 & 0 \\ 0 & 0 & 1 & 0 \\ -\frac{1}{2 \, m} & 0 & 0 & 1 \end{array}\right)$

and

In :
BL_to_NH.jacobian_det()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\frac{1}{2 \, m^{2}}$

The metric components with respect the coordinates $(T, R, \theta, \Phi)$ are computed by passing the chart NH to the method display():

In :
M.default_chart()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\mathcal{M},(t, r, {\theta}, {\phi})\right)$
In :
g.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}g = \left( \frac{2 \, m r}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} - 1 \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{m^{2} \cos\left({\theta}\right)^{2} + r^{2}}{m^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( m^{2} \cos\left({\theta}\right)^{2} + r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{2 \, m^{2} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + {\left(\frac{2 \, m^{3} r \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + r^{2}} + m^{2} + r^{2}\right)} \sin\left({\theta}\right)^{2} \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$
In :
g.display(NH)

Out:
$\newcommand{\Bold}{\mathbf{#1}}g = \left( -\frac{R^{2} m^{2} \cos\left({\theta}\right)^{4} + {\left(R^{4} {\epsilon}^{2} + 4 \, R^{3} {\epsilon} + 6 \, R^{2}\right)} m^{2} \cos\left({\theta}\right)^{2} - {\left(R^{4} {\epsilon}^{2} + 4 \, R^{3} {\epsilon} + 3 \, R^{2}\right)} m^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} T + \left( -\frac{R^{2} {\epsilon} m^{2} \sin\left({\theta}\right)^{4} - {\left(R^{4} {\epsilon}^{3} + 4 \, R^{3} {\epsilon}^{2} + 8 \, R^{2} {\epsilon} + 4 \, R\right)} m^{2} \sin\left({\theta}\right)^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} {\Phi} + \left( \frac{m^{2} \cos\left({\theta}\right)^{2} + {\left(R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + 1\right)} m^{2}}{R^{2}} \right) \mathrm{d} R\otimes \mathrm{d} R + \left( m^{2} \cos\left({\theta}\right)^{2} + {\left(R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + 1\right)} m^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{R^{2} {\epsilon} m^{2} \sin\left({\theta}\right)^{4} - {\left(R^{4} {\epsilon}^{3} + 4 \, R^{3} {\epsilon}^{2} + 8 \, R^{2} {\epsilon} + 4 \, R\right)} m^{2} \sin\left({\theta}\right)^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( -\frac{R^{2} {\epsilon}^{2} m^{2} \sin\left({\theta}\right)^{4} - {\left(R^{4} {\epsilon}^{4} + 4 \, R^{3} {\epsilon}^{3} + 8 \, R^{2} {\epsilon}^{2} + 8 \, R {\epsilon} + 4\right)} m^{2} \sin\left({\theta}\right)^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi}$

From now on, we use the near-horizon coordinates as the default ones on the spacetime manifold:

In :
M.set_default_chart(NH)
M.set_default_frame(NH.frame())


Hence NH becomes the default argument of display():

In :
g.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}g = \left( -\frac{R^{2} m^{2} \cos\left({\theta}\right)^{4} + {\left(R^{4} {\epsilon}^{2} + 4 \, R^{3} {\epsilon} + 6 \, R^{2}\right)} m^{2} \cos\left({\theta}\right)^{2} - {\left(R^{4} {\epsilon}^{2} + 4 \, R^{3} {\epsilon} + 3 \, R^{2}\right)} m^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} T + \left( -\frac{R^{2} {\epsilon} m^{2} \sin\left({\theta}\right)^{4} - {\left(R^{4} {\epsilon}^{3} + 4 \, R^{3} {\epsilon}^{2} + 8 \, R^{2} {\epsilon} + 4 \, R\right)} m^{2} \sin\left({\theta}\right)^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} {\Phi} + \left( \frac{m^{2} \cos\left({\theta}\right)^{2} + {\left(R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + 1\right)} m^{2}}{R^{2}} \right) \mathrm{d} R\otimes \mathrm{d} R + \left( m^{2} \cos\left({\theta}\right)^{2} + {\left(R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + 1\right)} m^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{R^{2} {\epsilon} m^{2} \sin\left({\theta}\right)^{4} - {\left(R^{4} {\epsilon}^{3} + 4 \, R^{3} {\epsilon}^{2} + 8 \, R^{2} {\epsilon} + 4 \, R\right)} m^{2} \sin\left({\theta}\right)^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( -\frac{R^{2} {\epsilon}^{2} m^{2} \sin\left({\theta}\right)^{4} - {\left(R^{4} {\epsilon}^{4} + 4 \, R^{3} {\epsilon}^{3} + 8 \, R^{2} {\epsilon}^{2} + 8 \, R {\epsilon} + 4\right)} m^{2} \sin\left({\theta}\right)^{2}}{R^{2} {\epsilon}^{2} + 2 \, R {\epsilon} + \cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi}$

## The near-horizon metric $h$ as the limit $\epsilon\to 0$ of the Kerr metric $g$¶

Let us define the near-horizon metric as the metric $h$ on $\mathcal{M}$ that is the limit $\epsilon\to 0$ of the Kerr metric $g$. The limit is taken by asking for a series expansion of $g$ with respect to $\epsilon$ up to the 0-th order (i.e. keeping only $\epsilon^0$ terms). This is achieved via the method truncate:

In :
g0 = g.truncate(eps, 0)


Since NH is the default chart and NH.frame() the default frame, we initialize the NH components of $h$ via

In :
h = M.lorentzian_metric('h')
h[:] = g0[:]
h.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}h = \left( -\frac{R^{2} m^{2} \cos\left({\theta}\right)^{4}}{\cos\left({\theta}\right)^{2} + 1} - \frac{6 \, R^{2} m^{2} \cos\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} + \frac{3 \, R^{2} m^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} T + \left( \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} {\Phi} + \left( \frac{m^{2} \cos\left({\theta}\right)^{2}}{R^{2}} + \frac{m^{2}}{R^{2}} \right) \mathrm{d} R\otimes \mathrm{d} R + \left( m^{2} \cos\left({\theta}\right)^{2} + m^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi}$

Some simplifications are in order:

In :
h.apply_map(lambda x: x.simplify_full())
h.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}h = \left( -\frac{R^{2} m^{2} \sin\left({\theta}\right)^{4} - 8 \, R^{2} m^{2} \sin\left({\theta}\right)^{2} + 4 \, R^{2} m^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} T + \left( \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} {\Phi} + \left( -\frac{m^{2} \sin\left({\theta}\right)^{2} - 2 \, m^{2}}{R^{2}} \right) \mathrm{d} R\otimes \mathrm{d} R + \left( -m^{2} \sin\left({\theta}\right)^{2} + 2 \, m^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi}$
In :
h.display_comp()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\begin{array}{lcl} h_{ \, T \, T }^{ \phantom{\, T}\phantom{\, T} } & = & -\frac{R^{2} m^{2} \sin\left({\theta}\right)^{4} - 8 \, R^{2} m^{2} \sin\left({\theta}\right)^{2} + 4 \, R^{2} m^{2}}{\cos\left({\theta}\right)^{2} + 1} \\ h_{ \, T \, {\Phi} }^{ \phantom{\, T}\phantom{\, {\Phi}} } & = & \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \\ h_{ \, R \, R }^{ \phantom{\, R}\phantom{\, R} } & = & -\frac{m^{2} \sin\left({\theta}\right)^{2} - 2 \, m^{2}}{R^{2}} \\ h_{ \, {\theta} \, {\theta} }^{ \phantom{\, {\theta}}\phantom{\, {\theta}} } & = & -m^{2} \sin\left({\theta}\right)^{2} + 2 \, m^{2} \\ h_{ \, {\Phi} \, T }^{ \phantom{\, {\Phi}}\phantom{\, T} } & = & \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \\ h_{ \, {\Phi} \, {\Phi} }^{ \phantom{\, {\Phi}}\phantom{\, {\Phi}} } & = & \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \end{array}$

As a check, we compare with Eq. (2.6) of Bardeen & Horowitz, Phys. Rev. D 60, 104030 (1999), which involves the bilinear form $$q = \frac{4m^2\sin^2\theta}{1+\cos^2\theta} \left( \mathrm{d}\Phi + R \mathrm{d} T \right)^2$$ We construct $q$ from the 1-forms $\mathrm{d} T$ and $\mathrm{d}\Phi$:

In :
dT = NH.coframe()
dT

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{d} T$
In :
dPh = NH.coframe()
dPh

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{d} {\Phi}$
In :
q = 4*m^2*sin(th)^2/(1+cos(th)^2) * (dPh + R*dT) * (dPh + R*dT)
q.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left( \frac{4 \, R^{2} m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} T + \left( \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} T\otimes \mathrm{d} {\Phi} + \left( \frac{4 \, R m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} T + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\Phi}\otimes \mathrm{d} {\Phi}$

We evaluate then $h-q$ to compare with Eq. (2.6) of Bardeen & Horowitz:

In :
(h - q).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left( R^{2} m^{2} \sin\left({\theta}\right)^{2} - 2 \, R^{2} m^{2} \right) \mathrm{d} T\otimes \mathrm{d} T + \left( -\frac{m^{2} \sin\left({\theta}\right)^{2} - 2 \, m^{2}}{R^{2}} \right) \mathrm{d} R\otimes \mathrm{d} R + \left( -m^{2} \sin\left({\theta}\right)^{2} + 2 \, m^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta}$
In :
s = (h - q)/(m^2*(1 + cos(th)^2))
s.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left( \frac{R^{2} m^{2} \sin\left({\theta}\right)^{2} - 2 \, R^{2} m^{2}}{{\left(\cos\left({\theta}\right)^{2} + 1\right)} m^{2}} \right) \mathrm{d} T\otimes \mathrm{d} T + \left( -\frac{m^{2} \sin\left({\theta}\right)^{2} - 2 \, m^{2}}{{\left(\cos\left({\theta}\right)^{2} + 1\right)} R^{2} m^{2}} \right) \mathrm{d} R\otimes \mathrm{d} R + \left( -\frac{m^{2} \sin\left({\theta}\right)^{2} - 2 \, m^{2}}{{\left(\cos\left({\theta}\right)^{2} + 1\right)} m^{2}} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta}$

Some simplifications are in order:

In :
s.apply_map(lambda x: x.subs({cos(th)^2: 1 - sin(th)^2}))
s.apply_map(lambda x: x.simplify_full())
s.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}-R^{2} \mathrm{d} T\otimes \mathrm{d} T + \frac{1}{R^{2}} \mathrm{d} R\otimes \mathrm{d} R +\mathrm{d} {\theta}\otimes \mathrm{d} {\theta}$

The above result shows the complete agreement between $h = m^2(1 + \cos^2\theta) s + q$ and the metric given by Eq. (2.6) of Bardeen & Horowitz.

### Non-degenerate character¶

A priori, the limit process defining $h$ ensures only that $h$ is a symmetric bilinear form. In order to establish that it is a proper metric on $\mathcal{M}$, there remains to show that $h$ is non-degenerate. Let us do it by computing the determinant of $h$'s components with respect to the NH coordinates:

In :
deth = h.determinant(frame=NH.frame())
deth.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\begin{array}{llcl} & \mathcal{M} & \longrightarrow & \mathbb{R} \\ & \left(t, r, {\theta}, {\phi}\right) & \longmapsto & -4 \, m^{8} \sin\left({\theta}\right)^{6} + 16 \, m^{8} \sin\left({\theta}\right)^{4} - 16 \, m^{8} \sin\left({\theta}\right)^{2} \\ & \left(T, R, {\theta}, {\Phi}\right) & \longmapsto & -4 \, m^{8} \sin\left({\theta}\right)^{6} + 16 \, m^{8} \sin\left({\theta}\right)^{4} - 16 \, m^{8} \sin\left({\theta}\right)^{2} \end{array}$
In :
deth.expr().factor()

Out:
$\newcommand{\Bold}{\mathbf{#1}}-4 \, {\left(\sin\left({\theta}\right)^{2} - 2\right)}^{2} m^{8} \sin\left({\theta}\right)^{2}$

Hence the determinant vanishes only for $\sin\theta = 0$, which corresponds simply to the standard coordinate singularity of spherical-type coordinates on the rotation axis. Away from the rotation axis, we have $\det h < 0$, which implies that $h$ is non-degenerate and furthermore, that it is has the signature $(-,+,+,+)$. Hence we conclude that that $h$ is a regular Lorentzian metric on $\mathcal{M}$.

We note that the metric $h$ is not asymptotically flat.

### Einstein equation for $h$¶

As a limit of solutions of the vaccum Einstein equation, $h$ is itself a solution of the vacuum Einstein equation, as we can check:

In :
h.ricci().display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{Ric}\left(h\right) = 0$

## Killing vectors of the near-horizon geometry¶

Let us first consider the vector field $\eta := \frac{\partial}{\partial\Phi}$:

In :
eta = M.vector_field(0, 0, 0, 1, name='eta', latex_name=r'\eta')
eta.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\eta = \frac{\partial}{\partial {\Phi} }$

It is a Killing vector of the near-horizon metric, since the Lie derivative of $h$ along $\eta$ vanishes:

In :
h.lie_derivative(eta).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}0$

This is not surprising since the components of $h$ are independent from $\Phi$.

Similarly, we can check that $\xi_1 := \frac{\partial}{\partial T}$ is a Killing vector of $h$, reflecting the independence of the components of $h$ from $T$:

In :
xi1 = M.vector_field(1, 0, 0, 0, name='xi1', latex_name=r'\xi_{1}')
xi1.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\xi_{1} = \frac{\partial}{\partial T }$
In :
h.lie_derivative(xi1).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}0$

The above two Killing vectors correspond respectively to the axisymmetry and the pseudo-stationarity of the Kerr metric. A third symmetry, which is not present in the original Kerr metric, is the invariance under the scaling $(T,R)\mapsto (\alpha T, R/\alpha)$, as it is clear on the metric components in Out. The corresponding Killing vector is

In :
xi2 = M.vector_field(T, -R, 0, 0, name='xi2', latex_name=r'\xi_{2}')
xi2.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\xi_{2} = T \frac{\partial}{\partial T } -R \frac{\partial}{\partial R }$
In :
h.lie_derivative(xi2).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}0$

Finally, a fourth Killing vector is

In :
xi3 = M.vector_field((T^2 + 1/R^2)/2, -R*T, 0, -1/R,
name='xi3', latex_name=r'\xi_{3}')
xi3.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\xi_{3} = \left( \frac{1}{2} \, T^{2} + \frac{1}{2 \, R^{2}} \right) \frac{\partial}{\partial T } -R T \frac{\partial}{\partial R } -\frac{1}{R} \frac{\partial}{\partial {\Phi} }$
In :
h.lie_derivative(xi3).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}0$

We shall see below that this Killing vector is actually related to the Killing vector $\frac{\partial}{\partial \tau}$ associated to the so-called global NHEK coordinates by $$\xi_3 = \frac{\partial}{\partial \tau} - \frac{1}{2} \frac{\partial}{\partial T}$$

## Determination of the symmetry group¶

We have four independent Killing vectors, $\eta$, $\xi_1$, $\xi_2$ and $\xi_3$, which implies that the symmetry group of the near-horizon geometry is a 4-dimensional Lie group $G$. Let us determine $G$ by investigating the structure constants of the basis $(\eta, \xi_1, \xi_2, \xi_3)$ of the Lie algebra of $G$. First of all, we notice that $\eta$ commutes with the other Killing vectors:

In :
for xi in [xi1, xi2, xi3]:
show(eta.bracket(xi).display())

$\newcommand{\Bold}{\mathbf{#1}}\left[\eta,\xi_{1}\right] = 0$
$\newcommand{\Bold}{\mathbf{#1}}\left[\eta,\xi_{2}\right] = 0$
$\newcommand{\Bold}{\mathbf{#1}}\left[\eta,\xi_{3}\right] = 0$

Since $\eta$ generates the rotation group $\mathrm{SO}(2)=\mathrm{U}(1)$, we may write that $G = \mathrm{U}(1)\times G_3$, where $G_3$ is a 3-dimensional Lie group, whose generators are $(\xi_1, \xi_2, \xi_3)$. Let us determine the structure constants of these three vectors. We have

In :
xi1.bracket(xi2).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left[\xi_{1},\xi_{2}\right] = \frac{\partial}{\partial T }$
In :
xi1.bracket(xi2) == xi1

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{True}$
In :
xi1.bracket(xi3).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left[\xi_{1},\xi_{3}\right] = T \frac{\partial}{\partial T } -R \frac{\partial}{\partial R }$
In :
xi1.bracket(xi3) == xi2

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{True}$
In :
xi2.bracket(xi3).display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left[\xi_{2},\xi_{3}\right] = \left( \frac{R^{2} T^{2} + 1}{2 \, R^{2}} \right) \frac{\partial}{\partial T } -R T \frac{\partial}{\partial R } -\frac{1}{R} \frac{\partial}{\partial {\Phi} }$
In :
xi2.bracket(xi3) == xi3

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{True}$

To summarize, we have

In :
all([xi1.bracket(xi2) == xi1,
xi1.bracket(xi3) == xi2,
xi2.bracket(xi3) == xi3])

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{True}$

To recognize a standard Lie algebra, let us perform a slight change of basis:

In :
vE = -sqrt(2)*xi3
vF = sqrt(2)*xi1
vH = 2*xi2


We have then the following commutation relations:

In :
all([vE.bracket(vF) == vH,
vH.bracket(vE) == 2*vE,
vH.bracket(vF) == -2*vF])

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{True}$

We recognize the Lie algebra $\mathfrak{sl}(2, \mathbb{R})$. Indeed, we have, using the representation of $\mathfrak{sl}(2, \mathbb{R})$ by traceless $2\times 2$ matrices:

In :
sl2 = lie_algebras.sl(QQ, 2, representation='matrix')  # QQ instead of RR to deal with an exact field
E,F,H = sl2.gens()

In :
E

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\begin{array}{rr} 0 & 1 \\ 0 & 0 \end{array}\right)$
In :
F

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\begin{array}{rr} 0 & 0 \\ 1 & 0 \end{array}\right)$
In :
H

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\begin{array}{rr} 1 & 0 \\ 0 & -1 \end{array}\right)$
In :
all([E.bracket(F) == H,
H.bracket(E) == 2*E,
H.bracket(F) == -2*F])

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{True}$

Hence, we have $$\mathrm{Lie}(G_3) = \mathfrak{sl}(2, \mathbb{R}).$$

At this stage, $G_3$ could be $\mathrm{SL}(2, \mathbb{R})$, $\mathrm{PSL}(2, \mathbb{R})=\mathrm{SL}(2, \mathbb{R})/\mathbb{Z}_2$ or $\overline{\mathrm{SL}(2, \mathbb{R})}$ (the universal covering group of $\mathrm{SL}(2, \mathbb{R})$). It cannot be $\mathrm{PSL}(2, \mathbb{R})$ because, as it appears clearly on $h$'s components, the transformation $(T,R) \mapsto (-T,-R)$ is an element of $G_3$ and, in $\mathrm{PSL}(2,\mathbb{R})$, this element would be identified with the identity due to the quotient by $\mathbb{Z}_2 = \{\mathrm{Id}, -\mathrm{Id}\}$ ($\mathrm{Id}$ being the identity). $G_3$ is actually $\mathrm{SL}(2, \mathbb{R})$. We conclude that the full isometry group of the near-horizon geometry is $$G = \mathrm{U}(1) \times \mathrm{SL}(2, \mathbb{R}).$$

## Expression of $h$ and the near-horizon Killing vectors in the Boyer-Lindquist basis¶

The Boyer-Lindquist components of the near-horizon metric $h$ are obtained by providing the argument BL to the method display:

In :
h.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}h = \left( -\frac{{\left(m^{2} - 2 \, m r + r^{2}\right)} \sin\left({\theta}\right)^{4} - 4 \, {\left(5 \, m^{2} - 6 \, m r + 2 \, r^{2}\right)} \sin\left({\theta}\right)^{2} + 4 \, m^{2} - 8 \, m r + 4 \, r^{2}}{4 \, {\left(m^{2} \cos\left({\theta}\right)^{2} + m^{2}\right)}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, {\left(2 \, m - r\right)} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( -\frac{m^{2} \sin\left({\theta}\right)^{2} - 2 \, m^{2}}{m^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( -m^{2} \sin\left({\theta}\right)^{2} + 2 \, m^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( -\frac{2 \, {\left(2 \, m - r\right)} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

We note that the Boyer-Lindquist components of $h$ do not depend on the parameter $\epsilon$, despite the change of coordinates NH $\to$ BL does.

We have established above that $$h = m^2 (1 + \cos^2\theta) s + q$$ Let us evaluate the Boyer-Lindquist expressions of $s$ and $q$:

In :
s.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left( -\frac{m^{2} - 2 \, m r + r^{2}}{4 \, m^{4}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{1}{m^{2} - 2 \, m r + r^{2}} \right) \mathrm{d} r\otimes \mathrm{d} r +\mathrm{d} {\theta}\otimes \mathrm{d} {\theta}$
In :
s.apply_map(factor, frame=BL.frame(), chart=BL, keep_other_components=True)
s.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}-\frac{{\left(m - r\right)}^{2}}{4 \, m^{4}} \mathrm{d} t\otimes \mathrm{d} t + \frac{1}{{\left(m - r\right)}^{2}} \mathrm{d} r\otimes \mathrm{d} r +\mathrm{d} {\theta}\otimes \mathrm{d} {\theta}$
In :
q.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left( \frac{{\left(4 \, m^{2} - 4 \, m r + r^{2}\right)} \sin\left({\theta}\right)^{2}}{m^{2} \cos\left({\theta}\right)^{2} + m^{2}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, {\left(2 \, m - r\right)} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( -\frac{2 \, {\left(2 \, m - r\right)} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$
In :
q.apply_map(factor, frame=BL.frame(), chart=BL, keep_other_components=True)
q.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\frac{{\left(2 \, m - r\right)}^{2} \sin\left({\theta}\right)^{2}}{{\left(\cos\left({\theta}\right)^{2} + 1\right)} m^{2}} \mathrm{d} t\otimes \mathrm{d} t + \left( -\frac{2 \, {\left(2 \, m - r\right)} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( -\frac{2 \, {\left(2 \, m - r\right)} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

Hence the identity $$q = \frac{\sin^2\theta}{1 + \cos^2\theta} \left( \frac{r - 2m}{m}\mathrm{d}t + 2 m\, \mathrm{d}\phi \right)^2$$

### Near-horizon Killing vectors in terms of Boyer-Lindquist coordinates¶

In :
eta.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\eta = \frac{\partial}{\partial {\phi} }$
In :
xi1.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\xi_{1} = \frac{2 \, m}{{\epsilon}} \frac{\partial}{\partial t } + \frac{1}{{\epsilon}} \frac{\partial}{\partial {\phi} }$

Given that for an extremal Kerr black hole $\Omega_H = 1/(2m)$, we recognize that $$\xi_1 = \frac{2m}{\epsilon} \chi$$ where $\chi := \frac{\partial}{\partial t} + \Omega_H \frac{\partial}{\partial \phi}$ is the Killing vector that is tangent to the horizon null generators on $\mathcal{H}$, or equivalently that is the null normal of the Killing horizon $\mathcal{H}$.

In :
xi2.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\xi_{2} = t \frac{\partial}{\partial t } + \left( m - r \right) \frac{\partial}{\partial r } + \frac{t}{2 \, m} \frac{\partial}{\partial {\phi} }$
In :
xi3.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\xi_{3} = \left( \frac{4 \, {\epsilon} m^{4} + {\left({\epsilon} m^{2} - 2 \, {\epsilon} m r + {\epsilon} r^{2}\right)} t^{2}}{4 \, {\left(m^{3} - 2 \, m^{2} r + m r^{2}\right)}} \right) \frac{\partial}{\partial t } + \frac{{\left({\epsilon} m - {\epsilon} r\right)} t}{2 \, m} \frac{\partial}{\partial r } + \left( \frac{12 \, {\epsilon} m^{4} - 8 \, {\epsilon} m^{3} r + {\left({\epsilon} m^{2} - 2 \, {\epsilon} m r + {\epsilon} r^{2}\right)} t^{2}}{8 \, {\left(m^{4} - 2 \, m^{3} r + m^{2} r^{2}\right)}} \right) \frac{\partial}{\partial {\phi} }$
In :
xi3.apply_map(factor, frame=BL.frame(), chart=BL, keep_other_components=True)
xi3.display(BL)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\xi_{3} = \frac{{\left(4 \, m^{4} + m^{2} t^{2} - 2 \, m r t^{2} + r^{2} t^{2}\right)} {\epsilon}}{4 \, {\left(m - r\right)}^{2} m} \frac{\partial}{\partial t } + \frac{{\epsilon} {\left(m - r\right)} t}{2 \, m} \frac{\partial}{\partial r } + \frac{{\left(12 \, m^{4} - 8 \, m^{3} r + m^{2} t^{2} - 2 \, m r t^{2} + r^{2} t^{2}\right)} {\epsilon}}{8 \, {\left(m - r\right)}^{2} m^{2}} \frac{\partial}{\partial {\phi} }$

We note that the BL components of $\xi_2$ are independent from $\epsilon$, while those of $\xi_1$ and $\xi_3$ are, with $\xi_1$ diverging when $\epsilon\to 0$ and $\xi_3$ vanishing when $\epsilon\to 0$.

### The Killing operator of $g$ applied to the near-horizon Killing vectors¶

In this part, we set the default chart and frame back to the Boyer-Lindquist ones:

In :
M.set_default_chart(BL)
M.set_default_frame(BL.frame())


The Levi-Civita connection $\nabla$ of $g$:

In :
nabla = g.connection()


The Killing form $\mathrm{K}v$ of a vector field $v$ is defined by $$(\mathrm{K}v)_{ab} := \nabla_a v_b + \nabla_b v_a,$$ where $v_a := g_{ab} v^b$. We implement it in SageMath via the following function:

In :
def killing_form(v):
Kv = 2*nabla(v.down(g)).symmetrize()
if v._name is not None:
Kv.set_name('K' + v._name, latex_name=r'\mathrm{K}' + str(latex(v)))
return Kv


The Killing form of $\eta$ is identically zero:

In :
Keta = killing_form(eta)
print(Keta)
Keta.display()

Field of symmetric bilinear forms Keta on the 4-dimensional Lorentzian manifold M

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{K}\eta = 0$

We recover the fact that $\eta$ is a Killing vector of $g$. Similarly, we have

In :
Kxi1 = killing_form(xi1)
print(Kxi1)
Kxi1.display()

Field of symmetric bilinear forms Kxi1 on the 4-dimensional Lorentzian manifold M

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{K}\xi_{1} = 0$

We recover the fact that $\xi_1 = (2m/\epsilon) \chi$ is a Killing vector of $g$.

But $\xi_2$ and $\xi_3$ are not Killing vectors of $g$:

In :
Kxi2 = killing_form(xi2)
print(Kxi2)
Kxi2.display()

Field of symmetric bilinear forms Kxi2 on the 4-dimensional Lorentzian manifold M

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{K}\xi_{2} = \left( -\frac{2 \, {\left({\left(m^{4} - m^{3} r\right)} \cos\left({\theta}\right)^{4} + m^{2} r^{2} - 2 \, m r^{3} + r^{4} - {\left(m^{4} - 2 \, m^{2} r^{2} + m r^{3}\right)} \cos\left({\theta}\right)^{2}\right)}}{m^{4} \cos\left({\theta}\right)^{4} + 2 \, m^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{{\left(m^{6} - 2 \, m^{5} r + m^{4} r^{2}\right)} \sin\left({\theta}\right)^{6} + 2 \, {\left(m^{6} + m^{5} r - 2 \, m^{4} r^{2} + m^{3} r^{3} - m^{2} r^{4}\right)} \sin\left({\theta}\right)^{4} - {\left(3 \, m^{6} - 7 \, m^{4} r^{2} + 8 \, m^{3} r^{3} - 3 \, m^{2} r^{4} - r^{6}\right)} \sin\left({\theta}\right)^{2}}{2 \, {\left(m^{5} \cos\left({\theta}\right)^{4} + 2 \, m^{3} r^{2} \cos\left({\theta}\right)^{2} + m r^{4}\right)}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{2 \, r}{m - r} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( 2 \, m r - 2 \, r^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{{\left(m^{6} - 2 \, m^{5} r + m^{4} r^{2}\right)} \sin\left({\theta}\right)^{6} + 2 \, {\left(m^{6} + m^{5} r - 2 \, m^{4} r^{2} + m^{3} r^{3} - m^{2} r^{4}\right)} \sin\left({\theta}\right)^{4} - {\left(3 \, m^{6} - 7 \, m^{4} r^{2} + 8 \, m^{3} r^{3} - 3 \, m^{2} r^{4} - r^{6}\right)} \sin\left({\theta}\right)^{2}}{2 \, {\left(m^{5} \cos\left({\theta}\right)^{4} + 2 \, m^{3} r^{2} \cos\left({\theta}\right)^{2} + m r^{4}\right)}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( -\frac{2 \, {\left({\left(m^{4} r^{2} - m^{3} r^{3} - {\left(m^{6} - m^{5} r\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{4} - {\left(m r^{5} - r^{6} + {\left(m^{5} r - m^{4} r^{2}\right)} \cos\left({\theta}\right)^{4} + 2 \, {\left(m^{3} r^{3} - m^{2} r^{4}\right)} \cos\left({\theta}\right)^{2}\right)} \sin\left({\theta}\right)^{2}\right)}}{m^{4} \cos\left({\theta}\right)^{4} + 2 \, m^{2} r^{2} \cos\left({\theta}\right)^{2} + r^{4}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$
In :
Kxi3 = killing_form(xi3)
print(Kxi3)
Kxi3.display()

Field of symmetric bilinear forms Kxi3 on the 4-dimensional Lorentzian manifold M

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{K}\xi_{3} = \left( -\frac{{\left({\epsilon} m^{4} - {\epsilon} m^{3} r\right)} t \cos\left({\theta}\right)^{4} - {\left({\epsilon} m^{4} - 2 \, {\epsilon} m^{2} r^{2} + {\epsilon} m r^{3}\right)} t \cos\left({\theta}\right)^{2} + {\left({\epsilon} m^{2} r^{2} - 2 \, {\epsilon} m r^{3} + {\epsilon} r^{4}\right)} t}{m^{5} \cos\left({\theta}\right)^{4} + 2 \, m^{3} r^{2} \cos\left({\theta}\right)^{2} + m r^{4}} \right) \mathrm{d} t\otimes \mathrm{d} t + \left( \frac{{\epsilon} m^{4} \cos\left({\theta}\right)^{4} + {\epsilon} r^{4} - 2 \, {\left(2 \, {\epsilon} m^{4} - {\epsilon} m^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}{2 \, {\left(m^{2} r^{2} - m r^{3} + {\left(m^{4} - m^{3} r\right)} \cos\left({\theta}\right)^{2}\right)}} \right) \mathrm{d} t\otimes \mathrm{d} r + \left( \frac{{\left({\epsilon} m^{6} - 2 \, {\epsilon} m^{5} r + {\epsilon} m^{4} r^{2}\right)} t \sin\left({\theta}\right)^{6} + 2 \, {\left({\epsilon} m^{6} + {\epsilon} m^{5} r - 2 \, {\epsilon} m^{4} r^{2} + {\epsilon} m^{3} r^{3} - {\epsilon} m^{2} r^{4}\right)} t \sin\left({\theta}\right)^{4} - {\left(3 \, {\epsilon} m^{6} - 7 \, {\epsilon} m^{4} r^{2} + 8 \, {\epsilon} m^{3} r^{3} - 3 \, {\epsilon} m^{2} r^{4} - {\epsilon} r^{6}\right)} t \sin\left({\theta}\right)^{2}}{4 \, {\left(m^{6} \cos\left({\theta}\right)^{4} + 2 \, m^{4} r^{2} \cos\left({\theta}\right)^{2} + m^{2} r^{4}\right)}} \right) \mathrm{d} t\otimes \mathrm{d} {\phi} + \left( \frac{{\epsilon} m^{4} \cos\left({\theta}\right)^{4} + {\epsilon} r^{4} - 2 \, {\left(2 \, {\epsilon} m^{4} - {\epsilon} m^{2} r^{2}\right)} \cos\left({\theta}\right)^{2}}{2 \, {\left(m^{2} r^{2} - m r^{3} + {\left(m^{4} - m^{3} r\right)} \cos\left({\theta}\right)^{2}\right)}} \right) \mathrm{d} r\otimes \mathrm{d} t + \left( \frac{{\epsilon} r t}{m^{2} - m r} \right) \mathrm{d} r\otimes \mathrm{d} r + \left( -\frac{{\left(2 \, {\epsilon} m^{4} - {\epsilon} m^{3} r\right)} \sin\left({\theta}\right)^{4} - {\left(2 \, {\epsilon} m^{4} - {\epsilon} m^{3} r - {\epsilon} m r^{3}\right)} \sin\left({\theta}\right)^{2}}{m r^{2} - r^{3} + {\left(m^{3} - m^{2} r\right)} \cos\left({\theta}\right)^{2}} \right) \mathrm{d} r\otimes \mathrm{d} {\phi} + \frac{{\left({\epsilon} m r - {\epsilon} r^{2}\right)} t}{m} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{{\left({\epsilon} m^{6} - 2 \, {\epsilon} m^{5} r + {\epsilon} m^{4} r^{2}\right)} t \sin\left({\theta}\right)^{6} + 2 \, {\left({\epsilon} m^{6} + {\epsilon} m^{5} r - 2 \, {\epsilon} m^{4} r^{2} + {\epsilon} m^{3} r^{3} - {\epsilon} m^{2} r^{4}\right)} t \sin\left({\theta}\right)^{4} - {\left(3 \, {\epsilon} m^{6} - 7 \, {\epsilon} m^{4} r^{2} + 8 \, {\epsilon} m^{3} r^{3} - 3 \, {\epsilon} m^{2} r^{4} - {\epsilon} r^{6}\right)} t \sin\left({\theta}\right)^{2}}{4 \, {\left(m^{6} \cos\left({\theta}\right)^{4} + 2 \, m^{4} r^{2} \cos\left({\theta}\right)^{2} + m^{2} r^{4}\right)}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} t + \left( -\frac{{\left(2 \, {\epsilon} m^{4} - {\epsilon} m^{3} r\right)} \sin\left({\theta}\right)^{4} - {\left(2 \, {\epsilon} m^{4} - {\epsilon} m^{3} r - {\epsilon} m r^{3}\right)} \sin\left({\theta}\right)^{2}}{m r^{2} - r^{3} + {\left(m^{3} - m^{2} r\right)} \cos\left({\theta}\right)^{2}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} r + \left( \frac{{\left({\left({\epsilon} m^{6} - {\epsilon} m^{5} r\right)} t \cos\left({\theta}\right)^{2} - {\left({\epsilon} m^{4} r^{2} - {\epsilon} m^{3} r^{3}\right)} t\right)} \sin\left({\theta}\right)^{4} + {\left({\left({\epsilon} m^{5} r - {\epsilon} m^{4} r^{2}\right)} t \cos\left({\theta}\right)^{4} + 2 \, {\left({\epsilon} m^{3} r^{3} - {\epsilon} m^{2} r^{4}\right)} t \cos\left({\theta}\right)^{2} + {\left({\epsilon} m r^{5} - {\epsilon} r^{6}\right)} t\right)} \sin\left({\theta}\right)^{2}}{m^{5} \cos\left({\theta}\right)^{4} + 2 \, m^{3} r^{2} \cos\left({\theta}\right)^{2} + m r^{4}} \right) \mathrm{d} {\phi}\otimes \mathrm{d} {\phi}$

## Global NHEK coordinates¶

Let us introduce the global NHEK coordinates $(\tau, y, \theta,\psi)$:

In :
GNH.<ta, y, th, ps> = M.chart(r"ta:\tau y th:(0,pi):\theta ps:(0,2*pi):periodic:\psi")
print(GNH)
GNH

Chart (M, (ta, y, th, ps))

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left(\mathcal{M},({\tau}, y, {\theta}, {\psi})\right)$

They are related to the near-horizon coordinates $(T,R,\theta,\Phi)$ via Eqs. (2.7)-(2.8) of J. Bardeen and G. T. Horowitz, Phys. Rev. D 60, 104030 (1999):

In :
GNH_to_NH = GNH.transition_map(NH, [sqrt(1+y^2)*sin(ta)/(y + sqrt(1+y^2)*cos(ta)),
y + sqrt(1+y^2)*cos(ta),
th,
ps + ln((cos(ta) + y*sin(ta))/(1 + sqrt(1+y^2)*sin(ta)))])
GNH_to_NH.display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left\{\begin{array}{lcl} T & = & \frac{\sqrt{y^{2} + 1} \sin\left({\tau}\right)}{\sqrt{y^{2} + 1} \cos\left({\tau}\right) + y} \\ R & = & \sqrt{y^{2} + 1} \cos\left({\tau}\right) + y \\ {\theta} & = & {\theta} \\ {\Phi} & = & {\psi} + \log\left(\frac{y \sin\left({\tau}\right) + \cos\left({\tau}\right)}{\sqrt{y^{2} + 1} \sin\left({\tau}\right) + 1}\right) \end{array}\right.$
In :
assume(R^2*T^2 - R^2 - 1<0)
assume(R>0)


The inverse transformation is

In :
GNH_to_NH.set_inverse(atan2(2*T*R^2, ((1 - T^2)*R^2 + 1)),
((1 + T^2)*R^2 - 1)/(2*R),
th,
Ph - ln(((1 - T*R)^2 + R^2)/sqrt(((1 + T^2)*R^2 - 1)^2 + 4*R^2)) )

Check of the inverse coordinate transformation:
ta == arctan2(2*y^2*cos(ta)*sin(ta) + 2*sqrt(y^2 + 1)*y*sin(ta) + 2*cos(ta)*sin(ta), 2*((cos(ta)^4 + 3*cos(ta)^2)*y^4 + cos(ta)^4 + (2*cos(ta)^4 + 3*cos(ta)^2)*y^2 + ((3*cos(ta)^3 + cos(ta))*y^3 + 3*y*cos(ta)^3)*sqrt(y^2 + 1))/((cos(ta)^2 + 1)*y^2 + 2*sqrt(y^2 + 1)*y*cos(ta) + cos(ta)^2))  **failed**
y == y  *passed*
th == th  *passed*
ps == ps + 1/2*log((cos(ta)^6 + 15*cos(ta)^4 + 15*cos(ta)^2 + 1)*y^6 + cos(ta)^6 + 3*(cos(ta)^6 + 10*cos(ta)^4 + 5*cos(ta)^2)*y^4 + 3*(cos(ta)^6 + 5*cos(ta)^4)*y^2 + 2*((3*cos(ta)^5 + 10*cos(ta)^3 + 3*cos(ta))*y^5 + 3*y*cos(ta)^5 + 2*(3*cos(ta)^5 + 5*cos(ta)^3)*y^3)*sqrt(y^2 + 1)) - log(y^2*cos(ta) + sqrt(y^2 + 1)*y + cos(ta)) + 1/2*log(y^2 + 1) - 1/2*log(abs((cos(ta)^4 + 6*cos(ta)^2 + 1)*y^4 + cos(ta)^4 + 2*(cos(ta)^4 + 3*cos(ta)^2)*y^2 + 4*((cos(ta)^3 + cos(ta))*y^3 + y*cos(ta)^3)*sqrt(y^2 + 1)))  **failed**
T == -2*R^2*T*abs(R^2*T^2 - R^2 - 1)/(R^4*T^4 - R^4 - 2*R^2*T^2 + (R^2*T^2 - R^2 - 1)*abs(R^2*T^2 - R^2 - 1) + 1)  **failed**
R == 1/2*(R^2*T^2 + R^2 + abs(R^2*T^2 - R^2 - 1) - 1)/R  **failed**
th == th  *passed*
Ph == Ph + log(-(R*T + 1)*abs(R^2*T^2 - R^2 - 1)/(R^2*T^2 - R*T*abs(R^2*T^2 - R^2 - 1) - R^2 - 1))  **failed**
NB: a failed report can reflect a mere lack of simplification.

In :
GNH_to_NH.inverse().display()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\left\{\begin{array}{lcl} {\tau} & = & \arctan\left(2 \, R^{2} T, -{\left(T^{2} - 1\right)} R^{2} + 1\right) \\ y & = & \frac{{\left(T^{2} + 1\right)} R^{2} - 1}{2 \, R} \\ {\theta} & = & {\theta} \\ {\psi} & = & {\Phi} - \log\left(\frac{{\left(R T - 1\right)}^{2} + R^{2}}{\sqrt{{\left({\left(T^{2} + 1\right)} R^{2} - 1\right)}^{2} + 4 \, R^{2}}}\right) \end{array}\right.$

### Plot of the near-horizon coordinates in terms of the global NHEK ones¶

In :
graph = NH.plot(GNH, ambient_coords=(y, ta), fixed_coords={th: pi/2, Ph: 0},
ranges={T: (-10, 10), R: (0.03, 12)}, color={T: 'red', R: 'grey'},
number_values={T: 17, R: 13}, plot_points=800) + \
NH.plot(GNH, ambient_coords=(y, ta), fixed_coords={th: pi/2, R: 0.03, Ph: 0},
ranges={T: (-60, 60)}, color={T: 'blue'}, thickness=2,
number_values={T: 33}, plot_points=400)
show(graph, xmin=-5, xmax=6) ### Expression of the near horizon metric $h$ in terms of the global NHEK coordinates¶

In :
h.display(GNH)

Out:
$\newcommand{\Bold}{\mathbf{#1}}h = \left( -\frac{m^{2} \cos\left({\theta}\right)^{4} + 2 \, m^{2} \cos\left({\theta}\right)^{2} + {\left(m^{2} \cos\left({\theta}\right)^{4} + 6 \, m^{2} \cos\left({\theta}\right)^{2} - 3 \, m^{2}\right)} y^{2} + m^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} + \left( \frac{4 \, m^{2} y \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\tau}\otimes \mathrm{d} {\psi} + \left( \frac{m^{2} \cos\left({\theta}\right)^{2} + m^{2}}{y^{2} + 1} \right) \mathrm{d} y\otimes \mathrm{d} y + \left( -m^{2} \sin\left({\theta}\right)^{2} + 2 \, m^{2} \right) \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{4 \, m^{2} y \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\tau} + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\psi}$
In :
h.apply_map(factor, frame=GNH.frame(), chart=GNH, keep_other_components=True)
h.display(GNH)

Out:
$\newcommand{\Bold}{\mathbf{#1}}h = \left( -\frac{{\left(y^{2} \cos\left({\theta}\right)^{4} + 6 \, y^{2} \cos\left({\theta}\right)^{2} + \cos\left({\theta}\right)^{4} - 3 \, y^{2} + 2 \, \cos\left({\theta}\right)^{2} + 1\right)} m^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\tau}\otimes \mathrm{d} {\tau} + \left( \frac{4 \, m^{2} y \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\tau}\otimes \mathrm{d} {\psi} + \left( \frac{{\left(\cos\left({\theta}\right)^{2} + 1\right)} m^{2}}{y^{2} + 1} \right) \mathrm{d} y\otimes \mathrm{d} y -{\left(\sin\left({\theta}\right)^{2} - 2\right)} m^{2} \mathrm{d} {\theta}\otimes \mathrm{d} {\theta} + \left( \frac{4 \, m^{2} y \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\tau} + \left( \frac{4 \, m^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1} \right) \mathrm{d} {\psi}\otimes \mathrm{d} {\psi}$

Let us check that we recover Eq. (2.9) of Bardeen & Horowitz, Phys. Rev. D 60, 104030 (1999). This is actually obvious for all the terms, except for $h_{\tau\tau}$. For the latter, the computation

In :
h00 = h[GNH.frame(),0,0,GNH].expr()
(h00 + m^2*(1 + cos(th)^2)*(1 + y^2)).simplify_full()

Out:
$\newcommand{\Bold}{\mathbf{#1}}\frac{4 \, m^{2} y^{2} \sin\left({\theta}\right)^{2}}{\cos\left({\theta}\right)^{2} + 1}$

shows that $$h_{\tau\tau} = m^2 \left[ - (1 + \cos^2\theta)(1 + y^2) + 4 \frac{y^2\sin^2\theta}{1 + \cos^2\theta} \right],$$ which yields a full agreement with Eq. (2.9) of Bardeen & Horowitz, up to an overall factor $2 m^2$.

### Expression of the $h$-Killing vector $\frac{\partial}{\partial\tau}$ in terms of $\xi_1$ and $\xi_3$¶

In :
GNH.frame().display(NH)

Out:
$\newcommand{\Bold}{\mathbf{#1}}\frac{\partial}{\partial {\tau} } = \left( \frac{R^{2} T^{2} + R^{2} + 1}{2 \, R^{2}} \right) \frac{\partial}{\partial T } -R T \frac{\partial}{\partial R } -\frac{1}{R} \frac{\partial}{\partial {\Phi} }$
In :
GNH.frame() == xi3 + xi1/2

Out:
$\newcommand{\Bold}{\mathbf{#1}}\mathrm{True}$

Hence we have: $$\frac{\partial}{\partial\tau} = \xi_3 + \frac{1}{2} \xi_1$$.