第1種完全楕円積分 $$K(k)=\int_{0}^{\frac{\pi}{2}}{\frac{1}{\sqrt{1-k^2\,\sin ^2\varphi}}\;d\varphi}$$ に成り立つ次の関係式 $$K(\frac{2\,\sqrt{x}}{x+1})=(x+1)\,K(x)$$ を示します。
kill(all)$
assume(x<1);
assume(-1<x);
この積分の計算は積分範囲を$0 \leq \varphi \leq \pi$に広げておく必要があります。被積分関数は$\varphi=\frac{\pi}{2}$で対称ですから積分の値は2倍になるだけです。つまり、 $$K(k)=\frac{1}{2}\,\int_{0}^{\pi}{\frac{1}{\sqrt{1-k^2\,\sin ^2\varphi}}\;d\varphi}$$ 以下の計算ではこの$\frac{1}{2}$を除いた積分の部分だけを計算します。後で忘れずに2で割ることにしましょう。
$k=\frac{2\,\sqrt{x}}{x+1}$を積分範囲を広げた積分の$k$に代入すると以下の積分になります。
F1:integrate(1/sqrt(1-4*x/(1+x)^2*sin(phi)^2),phi,0,%pi);
通分して、$x\gt0$に注意して$x+1$をくくり出します。
F2:substpart(xthru(part(F1,1)),F1,1);
平方根記号の中を展開します。
F3:substpart(expand(part(F2,2,1)),F2,2,1);
平方根記号の中を$x$の多項式として整理します。
F4:substpart(ratsimp(part(F3,2),x),F3,2);
$x$の係数に三角関数の倍角公式を使います。
F5:substpart(trigreduce(part(F4,2,1)),F4,2,1);
三角関数を指数関数で書き直します。ここで虚数単位が出てきます。
F6:exponentialize(F5);
分母の平方根記号の中身が因数分解できることを、因数分解の結果を展開することで示します。
FT1:(1+x*exp(2*%i*phi))*(1+x*exp(-2*%i*phi));
%,expand;
というわけでF6の式は以下の式と等しいことが分かります。
F7:substpart(FT1,F6,2,1,2,1);
一旦$(x+1)$の項を忘れて積分の変形に集中します。後で忘れずに$(x+1)$をかけることにします。
被積分関数を$\frac{1}{\sqrt{e^{-2\,i\,\varphi}\,x+1}}\,\frac{1}{\sqrt{e^{2\,i\,\varphi}\,x+1}}$と見ると$\frac{1}{\sqrt{1+t}}$の形をした2つの関数の積になっています。一旦それぞれを別々に冪級数に展開します。
niceindices(makegamma(powerseries(1/sqrt(1+t),t,0))),niceindicespref:[n];
最初の項は$t=e^{-2\,i\,\varphi}\,x$なのでこの代入を行います。
%,t:exp(-2*%i*phi)*x;
第1項で$n=0$の場合1になることから第2項の1を総和の中に取り込みます。
F8:substpart(0,part(%,1),2,3);
総和のインデックス変数を$m$に変えて冪級数展開を求めます。
niceindices(makegamma(powerseries(1/sqrt(1+t),t,0))),niceindicespref:[m];
F7の被積分関数の第2項なので$t=e^{2\,i\,\varphi}\,x$の代入を行います。
%,t:exp(2*%i*phi)*x;
第2項の1を総和の$m=0$として取り込みます。
F9:substpart(0,part(%,1),2,3);
従ってF7の被積分関数は次の式に等しくなります。
F8*F9;
この式は2つの無限級数の積になっており、展開することで$0\le n, m\lt \infty$の全ての組み合わせについて積を取ることになります。和の順番を変更し入れ子にすることで次の式と等しいことが分かります。
F10:%pi*sum(sum(part(F8,2,1)*part(F9,2,1),m,0,inf),n,0,inf);
2重総和の内側の総和を取り出します。
G1:part(F10,2,1,1);
$x^n$は$m$と無関係なので総和の外にくくり出すことが来ます。
G2:x^n*substpart(part(G1,1)/x^n,G1,1);
従ってF10は次の式と等しくなります。
F11:substpart(G2,F10,2,1,1);
F7の被積分関数がこの2重総和と等しいことが分かりました。積分変数$\varphi$でこの式を積分をすると、積分変数に関係する部分は以下の部分式だけです。
G3:part(F11,2,1,1,2,1,1,1);
$n,m$はどちらも0以上の整数であることに注意します。すると積分の値はm=nの場合にはその値に関わらず$\pi$になります。
integrate(G3,phi,0,%pi),m=k,n=k;
また$n\neq m$の場合にはそれらの値に関わらず積分の値は0になります。例えば$m=4, n=9$で試しに計算してみます(これが成り立つのは積分範囲が$0\le\varphi\le\pi$の場合です。$0\le\varphi\le\frac{\pi}{2}$では上手くいきません)。
integrate(G3,phi,0,%pi),m=4,n=9;
これらのことからF11を$\varphi$で積分すると内側の総和は$m=n$の場合だけ積分の値が$\pi$として残り、それ以外の$m,n$の組み合わせは積分値が0になることから消えてしまいます。従ってF11の2重総和の内側の総和は次の式と等しいことが分かります。
G4:substpart(%pi,substpart(n,substpart(n,G2,2,3),2,4),2,1,1,1);
この総和は自明に簡約することが出来ます。
G5:G4,simpsum:true;
上記のG5の式で内側の総和を置き換えることでF7の積分は以下の式に変形できます。
F12:substpart(G5,F11,2,1,1);
以下はこの式を超幾何関数の形に変形していきます。 まずポッホハマー記号$\left(\frac{1}{2}\right)_n$を思い出します。
pochhammer(1/2,n);
SB-KERNEL:REDEFINITION-WITH-DEFUN: redefining MAXIMA::SIMP-UNIT-STEP in DEFUN SB-KERNEL:REDEFINITION-WITH-DEFUN: redefining MAXIMA::SIMP-POCHHAMMER in DEFUN
$\left(\frac{1}{2}\right)_n$を単純にガンマ関数で表示すると以下のようになりますが、これではちょっと上手くいきません。
makegamma(%);
ポッホハマー記号について次の等式が成り立ちます。
PoId:pochhammer(1-x,n)=gamma(x)*(-1)^n/gamma(x-n);
この等式で$x=\frac{1}{2}$を代入すると次の式を得ます。
PoId,x:1/2;
$\Gamma\left(\frac{1}{2}-n\right)$を作り出すことが出来ました。この式をこのガンマ関数について解いてみます。
PoId2:solve(%,gamma(1/2-n));
この式をF13に代入します。
F13:F12,PoId2;
ガンマ関数を階乗に直してみます。
makefact(F13);
F7の積分を変形して上記の式が得られました。この式を超幾何関数の定義と見比べれば $$\pi\,F\left(\frac{1}{2},\frac{1}{2};1,x^2\right)$$ と等しいことが分かります。
忘れずに$(x+1)$を掛けて2で割り $$(x+1)\,\frac{\pi}{2}\,F\left(\frac{1}{2},\frac{1}{2};1,x^2\right)$$ を得ます。
既に証明した $$\int_{0}^{\frac{\pi}{2}}{\frac{1}{\sqrt{1-k^2\,\sin ^2\vartheta}}\;d\vartheta}=\frac{\pi\,F\left( \left. \begin{array}{c}\frac{1}{2},\;\frac{1}{2}\\1\end{array} \right |,k^2\right)}{2}$$ と合わせると、 $$(x+1)\,K(x)$$ となります。というわけで、 $$K(\frac{2\,\sqrt{x}}{x+1})=(x+1)\,K(x)$$ が証明できました。